Excel VBA根据选择选择多个单元格

Question

我想根据选择选择多个单元格。
这是我的代码:

Private Sub CommandButton1_Click()

Selection.EntireRow.Select

End Sub

我想选择多个单元格中的前四列行，而不是整行。如何实现？
this is my Excel worksheet

Answer 1

选择非连续范围的行

将代码复制到标准模块中，例如Module1 .

在您的命令按钮单击事件中，按以下方式使用任一过程名称:

Private Sub CommandButton1_Click()
    selectRowsOfListObject
End Sub

或者

Private Sub CommandButton1_Click()
    selectRowsOfFirstFourColumns
End Sub

第一个过程将只选择ActiveSheet 中第一个(结构化)表中选定单元格的行。 .表格数据( DataBodyRange )之外的任何单元格都将被忽略。

第二个过程将选择前四列中所选单元格的所有行范围，在ActiveSheet的前四列中。 .在前四列之外选择的任何单元格都将被忽略

当代码将引用“包含”命令按钮的工作表时，每个或两个代码都可以与任何工作表上的命令按钮一起使用。

如果您希望另一个工作表上的命令按钮始终引用第一个工作表，您将不得不创建对第一个工作表的引用:
代替

Set ws = ActiveSheet

使用例如

Set ws = wb.Worksheets("Sheet1")

为了更好地理解差异，您可以为第二个代码添加另一个命令按钮，然后测试它们中的每一个。

代码

Option Explicit

Sub selectRowsOfListObject()
    Dim wb As Workbook
    Set wb = ThisWorkbook
    Dim ws As Worksheet
    Set ws = ActiveSheet
    Dim tbl As ListObject
    Set tbl = ws.ListObjects(1)
    If Selection.Worksheet.Name = ws.Name Then
        If TypeName(Selection) = "Range" Then
            Dim rng As Range
            Set rng = Intersect(Selection, tbl.DataBodyRange)
            If Not rng Is Nothing Then
                Set rng = Intersect(rng.Rows.EntireRow, tbl.DataBodyRange.Rows)
            End If
            If Not rng Is Nothing Then
                rng.Select
            End If
        End If
    End If
End Sub

Sub selectRowsOfFirstFourColumns()
    Dim wb As Workbook
    Set wb = ThisWorkbook
    Dim ws As Worksheet
    Set ws = ActiveSheet
    If Selection.Worksheet.Name = ws.Name Then
        If TypeName(Selection) = "Range" Then
            Dim rng As Range
            Set rng = Intersect(Selection.Rows.EntireRow, _
                                ws.Columns(1).Resize(, 4))
            If Not rng Is Nothing Then
                rng.Select
            End If
        End If
    End If
End Sub