vba - 从 Excel 运行 Access 查询

Question

我正在尝试从 excel 访问中运行查询，然后使用 VBA 中的 ADO 将这些结果拉入 excel 文档。不幸的是，我无法弄清楚如何运行访问查询，以便将 Excel 工作表的事件单元格中的数据用作访问查询中的条件。

我正在运行 Excel 和 Access 2007。我在下面包含了到目前为止的代码。在此先感谢您的帮助。

Sub testdb()

Dim con As ADODB.Connection
Dim rs As ADODB.Recordset
Set con = New ADODB.Connection
With con
.Provider = "Microsoft.ACE.OLEDB.12.0"
.Open "H:\WBC\Lukas\STOP.accdb"
End With
con.Execute "HPRSearch"
   'the criteria field is 'Input', and I need to pull it from the active cell on the Excel Sheet
End Sub

Answer 1

您需要做的第一件事是在 Access 中设置参数化查询。比如说，Query1 是(其中 ID 是一个整数):

SELECT ID FROM Table1 WHERE ID = [MyID];

[MyID] 周围的括号如果不能解析为字段名称，将被视为参数。现在，假设我们要恢复 ID 为 1 的记录。在 Excel 中设置您的代码:

Sub testdb()

    Dim con As ADODB.Connection
    Dim cmd As ADODB.Command
    Dim prm As ADODB.Parameter
    Dim rs As ADODB.Recordset

    Set con = New ADODB.Connection
    Set cmd = New ADODB.Command

    With con
        .Provider = "Microsoft.ACE.OLEDB.12.0"
        .Open "H:\WBC\Lukas\STOP.accdb"
    End With

    With cmd
        .ActiveConnection = con
        .CommandText = "Query1"
        .CommandType = adCmdStoredProc

        .Parameters.Append cmd.CreateParameter("MyID", adInteger, adParamInput)
        .Parameters("MyID") = 1
    End With

    Set rs = New ADODB.Recordset
    rs.Open cmd

    Do Until rs.EOF
        Debug.Print rs.Fields("ID").Value
        rs.MoveNext
    Loop

    rs.Close
    con.Close

    Set cmd = Nothing
    Set rs = Nothing
    Set prm = Nothing
    Set con = Nothing

End Sub

此引用 adInteger 在此行中找到

.Parameters.Append cmd.CreateParameter("MyID", adInteger, adParamInput)

应替换为代表查询中参数的变量类型的正确常量(参见此处:http://www.w3schools.com/ado/met_comm_createparameter.asp)。在您的情况下，您将设置此行中表示的 Parameter 值

.Parameters("MyID") = 1

与您的单元格中的值。

就是这样。因此，您创建 Connection，创建 Command 对象(本质上是对 Access 查询的引用)，设置 Command 对象的属性，包括参数，然后将结果带回记录集中。然后遍历记录集并使用这些值执行您想要的操作。