excel - PowerPoint 链接对象的新驱动器映射 - VBA 解决方案

Question

PowerPoint 中的所有链接对象(链接到 excel)不再被识别，因为 IT 已将服务器迁移到新路径并关闭旧路径。

我曾尝试使用 (https://exceloffthegrid.com/edit-links-in-powerpoint-using-vba/) 下面的宏，但由于旧服务器不再运行，当宏尝试打开旧文件路径时，它会出错

有替代解决方案吗？

Sub EditPowerPointLinks()

Dim oldFilePath As String
Dim newFilePath As String
Dim pptPresentation As Presentation
Dim pptSlide As Slide
Dim pptShape As Shape

'The old file path as a string (the text to be replaced)
oldFilePath = "String of\File Path\To Be Replaced\Excel File.xlsx"

'The new file path as a string (the text to replace with)
newFilePath = "String of\New File Path\Excel File 2.xlsx"

'Set the variable to the PowerPoint Presentation
Set pptPresentation = ActivePresentation

'Loop through each slide in the presentation
For Each pptSlide In pptPresentation.Slides

    'Loop through each shape in each slide
    For Each pptShape In pptSlide.Shapes

        'Find out if the shape is a linked object or a linked picture
        If pptShape.Type = msoLinkedPicture Or pptShape.Type _ 
        = msoLinkedOLEObject Then

            'Use Replace to change the oldFilePath to the newFilePath
            pptShape.LinkFormat.SourceFullName = Replace(LCase _
            (pptShape.LinkFormat.SourceFullName), LCase(oldFilePath), newFilePath)

        End If
    Next
Next

'Update the links
pptPresentation.UpdateLinks


End Sub

Answer 1

你的代码没问题，我也测试过。

新链接的设置由应用程序处理不同:

如果你设置一个新的SourceFullName链接图片(Shape.Type = msoLinkedPicture)，
应用程序接受任何链接，并且代码不会引发错误。

如果您尝试设置新的SourceFullName对于链接的 OLE 对象 (Shape.Type = msoLinkedOLEObject)，应用程序会立即测试新文件是否真的存在。
如果链接的 OLE 对象不存在，您将收到错误消息。

结果:您必须确保新路径指向现有文件(并且您需要适当的访问权限)。