haskell - 如果索引列表遍历不匹配，则返回 ‘Nothing’

Question

我是 lens 的新手并尝试使用它对嵌套结构进行许多小的修改，这可能会失败并可能返回额外的结果:

element -> Maybe element
element -> Maybe (result, element)

如何通过索引修改内部结构，同时返回 Nothing如果索引不存在？如果我使用 traverseOf + ix :

type Thing = (String, [Int])

exampleThing :: Thing
exampleThing = ("example", [0, 1])

predMaybe :: Int -> Maybe Int
predMaybe x
  | x == 0 = Nothing
  | otherwise = Just (pred x)

decrementThingAt :: Int -> Thing -> Maybe Thing
decrementThingAt i = traverseOf (_2 . ix i) predMaybe

> decrementThingAt 1 exampleThing
Just ("example",[0,0])

> decrementThingAt 0 exampleThing
Nothing

然后，如果索引不存在，这会默默地返回未修改的结构:

> decrementThingAt 2 exampleThing
Just ("example",[0,1])

而我想返回 Nothing这里也是。如果可能的话，我想在镜头组合“内部”进行。我知道我可以使用 preview/^? “外”获取Maybe根据光学元件是否匹配任何目标:

> preview (_2 . ix 1) exampleThing
Just 1

> preview (_2 . ix 2) exampleThing
Nothing

但我希望能够写出像 traverseOf (_2 . ix i . previewed) predMaybe 这样的东西.我看到了一些“在外面”做这件事的尴尬方式，比如 foldMapOf :

decrementThingAt i = getFirst . foldMapOf (_2 . ix i) (First . predMaybe)

但是有没有办法让所有东西都在同一个管道中，这样我就不会反复/明确地拆卸和重新组装结构？
我也不太明白如何将它与返回额外结果结合起来。目前我正在使用StateT和 zoom像这样:

import Control.Lens (_1, zoom)
import Control.Monad.Trans.State (StateT, runStateT)
import Data.List (uncons)

-- NB: uncons :: [a] -> Maybe (a, [a])

pop :: Thing -> Maybe (Char, Thing)
pop = runStateT $ zoom _1 $ StateT uncons

> pop exampleThing
Just ('e',("xample",[0,1]))

> pop ("", [0, 1])
Nothing

但我仍然不知道如何在缺少索引的情况下使用它，例如，使用 type ThingMaybe = (Maybe String, [Int])如果 Maybe 则失败是 Nothing .

Answer 1

你所要求的是不可能的。要了解原因，让我们看看您的 decrementThingAt例子。假设你想出了一些你想要的遍历。也就是说，你可以写

decrementThingAt :: Int -> Thing -> Maybe Thing
decrementThingAt i = traverseOf myTrav predMaybe

这样

> decrementThingAt 1 exampleThing
Just ("example",[0,0])

> decrementThingAt 2 exampleThing
Nothing

现在，让我们探索一下这个功能:

unknown :: Int -> Thing -> Thing
unknown i = myTrav %~ id

任何正常遍历，unknown n t == t对于 n 的所有(类型正确)选择和 t , 但使用 myTrav ，这已经不清楚了。如果您调用unknown 2 exampleThing ，大概你希望它返回... Nothing ?这在类型级别甚至没有意义。
换个角度看，不能构造遍历myTrav出于同样的原因，你跑了多少次

> traverse predMaybe []
Just []

你永远不会得到 Nothing .遍历ix基本上过滤掉列表中你调用的元素predMaybe开，当你 ix在不存在的索引上，就像您过滤掉了所有元素一样。最终没有调用 predMaybe ，所以无法返回 Nothing .
正如您正确识别的那样，做您正在寻找的正确方法是“在”遍历之外。这是有道理的:它与您声明使用 predMaybe 的级别相同。 , 毕竟是 Maybe应用程序正在发挥作用。例如，您使用 First和 foldMapOf之所以有效，是因为 First是一个具有 mempty ≈ Nothing 属性的幺半群，如你所愿。

在返回附加结果时，我喜欢使用 (a,)仿函数:

import Data.Functor.Compose

pop :: Thing -> Maybe (Char, Thing)
pop = getCompose . _1 (Compose . uncons)

-- Or if you prefer using all the lens operators:
-- pop t = getCompose $ t & _1 %%~ (Compose . uncons)

在这种情况下，由于需要使用 Compose，它变得更加复杂了。 ，但它仍然会做我想做的事。
至于退货Nothing当索引丢失时，您将遇到我上面描述的相同问题。

一些选项
对于它的值(value)，我相信实现您正在寻找的目标的最简单方法不是在“内部”级别进行，而是在外部级别进行，并且没有理由最终会“重复/明确拆卸和重新组装结构”。考虑这样的事情:

maybeToAny :: Maybe a -> Compose Maybe ((,) Any) a
maybeToAny = Compose . fmap (Any True,)

getIfAny :: Compose Maybe ((,) Any) a -> Maybe a
getIfAny (Compose Nothing) = Nothing
getIfAny (Compose (Just (Any False, _))) = Nothing
getIfAny (Compose (Just (Any True, a))) = Just a

decrementThingAt :: Int -> Thing -> Maybe Thing
decrementThingAt i = getIfAny . traverseOf (_2 . ix i) (maybeToAny . predMaybe)

这里的想法是我们使用 Any检查 maybeToAny . predMaybe 的值曾经被称为。如果是，那么 Any值为 True ，我们可以产生结果值，否则我们的遍历一定是错过了，所以我们返回Nothing .

如果你真的想在 optic 的“内部”执行此操作，我们还可以按照相同的原则进行伪遍历:

ixj :: Ixed m => Index m -> Traversal' (Maybe m) (IxValue m)
ixj i _ Nothing = pure Nothing
ixj i afb (Just s) =
  let t' = getCompose $ s & ix i %%~ Compose . fmap (Any True,) . afb
      go (Any True, t)  = Just t
      go (Any False, _) = Nothing
  in go <$> t'

请注意，我们需要 s类型为 Maybe m而不仅仅是 m这样我们就可以失败。不幸的是，这不是真正的遍历，因为它不遵守遍历定律(整个失败的想法与光学的工作原理相反)。我仍然设法想出了一些东西，但它有点难看:

finside :: Applicative f => ALens s t a b -> Lens (f s) (f t) (f a) (f b)
finside (cloneLens -> l) = lens (fmap $ getConst . l Const) (liftA2 $ flip (l .~))

decrementThingAt :: Int -> Thing -> Maybe Thing
decrementThingAt i = join . traverseOf (finside _2 . ixj i) predMaybe . Just

(我不确定镜头库中是否已经存在 finside 或类似的东西。我也不确定它产生的内容是否始终遵守镜头定律。)