vb6 用 API 抑制键盘敲击？ (制作热键)

Question

我已经搜索过，但似乎找不到答案，因此我们将不胜感激。

我想制作一个热键，但是当按下热键时，我不希望显示实际的“字符”，而只希望显示要执行的操作。

例如，我有这个:

 Private Declare Function GetAsyncKeyState Lib "user32" _
 (ByVal vKey As KeyCodeConstants) As Long

 Private Const VK_A = &H41

 Private Sub keyboardTimer001_Timer()
    If KeyDown(VK_A) Then
       ' do my stuff, but DONT DISPLAY the letter "A"
    End If
 end sub

所以这基本上只有一个计时器(间隔 1)检查异步键盘。如果它检测到按下了字母“a”，我就会执行一个操作。但我希望它在不打印字母“a”的情况下执行此操作。 如何从键盘缓冲区中删除该键/防止其显示？ (旁注 - 不确定像“PeekMessage”这样的东西是否有效 - 如果是的话 - 有谁知道我在哪里可以找到一个好的 vb6 代码示例，在那里我可以查看像“ctrl+a”或“ctrl+alt+a”这样的东西等等，然后只是清除缓冲区，然后执行我的操作？)

谢谢!

Answer 1

您可以结合使用 RegisterHotKey 和 PeekMessage。以下代码定义了 Key-A 和 Ctrl-A 来执行操作:

主窗体

Option Explicit

Private Done As Boolean

Private Sub Form_Activate()
   Done = False
   RegisterHotKey Me.hWnd, &HBBBB&, MOD_NONE, vbKeyA
   RegisterHotKey Me.hWnd, &HBBBA&, MOD_CONTROL, vbKeyA
   ProcessMessages
End Sub

Private Sub ProcessMessages()
   Dim Message As Msg

   Do While Not Done
      WaitMessage

      If PeekMessage(Message, Me.hWnd, WM_HOTKEY, WM_HOTKEY, PM_REMOVE) Then
         If Message.wParam = &HBBBB& Then
            MsgBox "This is my Key-A action"
         ElseIf Message.wParam = &HBBBA& Then
            MsgBox "This is my Ctrl-A action"
         End If
      End If

      DoEvents
   Loop
End Sub

Private Sub Form_Unload(Cancel As Integer)
   Done = True
   Call UnregisterHotKey(Me.hWnd, &HBBBB&)
   Call UnregisterHotKey(Me.hWnd, &HBBBA&)
End Sub

上面的代码运行良好，但在生产应用程序中我可能倾向于对主窗口进行子类化。如果您更喜欢子类化，则需要使用您选择的技术并将 ProcessMessages 方法替换为如下内容:

Private Function ISubclass_WindowProc(ByVal hwnd As Long, ByVal iMsg As Long, ByVal wParam As Long, ByVal lParam As Long) As Long
   Select Case iMsg
      Case WM_HOTKEY
         If wParam = &HBBBB& Then
            MsgBox "This is my Key-A action"
         ElseIf wParam = &HBBBA& Then
            MsgBox "This is my Ctrl-A action"
         End If
   End Select
End Function

正如您所看到的，子类化更加清晰一些。当然，你需要定义 Win API 的东西。因此，在模块中放置以下代码:

模块

Option Explicit

Public Declare Function RegisterHotKey Lib "user32" (ByVal hWnd As Long, ByVal id As Long, ByVal fsModifiers As Long, ByVal vk As Long) As Long
Public Declare Function UnregisterHotKey Lib "user32" (ByVal hWnd As Long, ByVal id As Long) As Long
Public Declare Function PeekMessage Lib "user32" Alias "PeekMessageA" (lpMsg As Msg, ByVal hWnd As Long, ByVal wMsgFilterMin As Long, ByVal wMsgFilterMax As Long, ByVal wRemoveMsg As Long) As Long
Public Declare Function WaitMessage Lib "user32" () As Long

Public Const MOD_NONE = &H0
Public Const MOD_ALT = &H1
Public Const MOD_CONTROL = &H2
Public Const MOD_SHIFT = &H4
Public Const MOD_WIN = &H8
Public Const PM_REMOVE = &H1
Public Const WM_HOTKEY = &H312

Public Type POINTAPI
   x As Long
   y As Long
End Type

Public Type Msg
   hWnd As Long
   Message As Long
   wParam As Long
   lParam As Long
   time As Long
   pt As POINTAPI
End Type