delphi - 检测可编辑 TWebBrowser 中的更改

标签 delphi delphi-xe7 twebbrowser

我正在将 HTML 本地文件加载到 TWebBrowser 中，如下所示:

procedure TForm1.FormCreate(Sender: TObject);
begin
  WebBrowser1.Navigate('file:///C:\Tmp\input.html');
end;

在 TWebBrowser.OnDocumentComplete 事件处理程序中，我将其设置为可编辑:

procedure TForm1.WebBrowser1DocumentComplete(ASender: TObject;
  const pDisp: IDispatch; const URL: OleVariant);
begin
  (WebBrowser1.Document as IHTMLDocument2).designMode := 'on';
end;

一旦用户通过 TWebBrowser 应用任何更改(即:他写了一些内容...)，我就需要收到通知，但我看不到任何 OnChanged > 或类似的事件处理程序。

我 try catch WM_PASTE 和 WM_KEYDOWN 但我的代码从未执行:

  TMyWebBrowser = class(TWebBrowser)
  public
    procedure WM_Paste(var Message: TWMPaste); message WM_PASTE;
    procedure WM_KeyDown(var Message: TWMKeyDown); message WM_KEYDOWN;
  end;

...

procedure TMyWebBrowser.WM_Paste(var Message: TWMPaste);
begin
  inherited;
  ShowMessage('Paste');
end;

procedure TMyWebBrowser.WM_KEYDOWN(var Message: TWMKeyDown);
begin
  inherited;
  ShowMessage('KeyDown');
end;

我也尝试过设置 WindowProc 属性，但没有成功。

最佳答案

要在设计模式下捕获对文档的更改，您应该使用其 IMarkupContainer2注册接口(interface) IHTMLChangeSink通过 RegisterForDirtyRange方法。这个过程非常简单 - 实现IHTMLChangeSink，从WebBrowser1.Document获取IMarkupContainer2并调用其RegisterForDirtyRange方法，但是有一个问题。

当您更改 IHTMLDocument2 的 designMode 时，TWebBrowser 控件将重新加载当前文档，并丢失所有已注册的更改接收器。因此，您应该在将文档置于设计模式后注册它。之后，您通过 IHTMLChangeSink.Notify 方法收到更改通知。

但是还有另一个问题。由于进入设计模式会导致文档重新加载，进而导致将文档的 readyState 属性更改为 'loading'，然后连续更改为 'complete' 。您的更改接收器将收到这些 readyState 更改通知。请注意，进入设计模式后不会调用TWebBrowser.OnDocumentComplete。这就是为什么您应该忽略任何通知，直到文档在设计模式下完全重新加载。

另一个小复杂之处是，RegisterForDirtyRange 创建了一个 cookie，您需要维护该 cookie，以便取消注册更改接收器。由于无论如何您都需要一个类来实现 IHTMLChangeSink，因此它还可以封装设计模式状态和更改注册。

uses
  System.SysUtils, SHDocVw, MSHTML;

const
  DesignMode: array[Boolean] of string = ('off', 'on');

type
  TWebBrowserDesign = class(TInterfacedObject, IHTMLChangeSink)
  private
    FDirtyRangeCookie: LongWord;
    FDocumentComplete: Boolean;
    FHTMLDocument2: IHTMLDocument2;
    FMarkupContainer2: IMarkupContainer2;
    FOnChange: TProc;
    { IHTMLChangeSink }
    function Notify: HResult; stdcall;
  public
    constructor Create(WebBrowser: TWebBrowser; const AOnChange: TProc);
    destructor Destroy; override;
  end;

constructor TWebBrowserDesign.Create(WebBrowser: TWebBrowser; const AOnChange: TProc);
begin
  inherited Create;
  if not Assigned(WebBrowser) then
    raise Exception.Create('Web browser control missing.');
  if not Supports(WebBrowser.Document, IHTMLDocument2, FHTMLDocument2) then
    raise Exception.Create('No HTML document loaded.');
  FHTMLDocument2.designMode := DesignMode[True];
  if Supports(WebBrowser.Document, IMarkupContainer2, FMarkupContainer2) then
  begin
    if FMarkupContainer2.RegisterForDirtyRange(Self, FDirtyRangeCookie) <> S_OK then
      FDirtyRangeCookie := 0
    else
      _Release;
  end;
  FOnChange := AOnChange;
end;

destructor TWebBrowserDesign.Destroy;
begin
  if Assigned(FMarkupContainer2) and (FDirtyRangeCookie <> 0) then
    FMarkupContainer2.UnRegisterForDirtyRange(FDirtyRangeCookie);
  if Assigned(FHTMLDocument2) then
    FHTMLDocument2.designMode := DesignMode[False];
  inherited;
end;

function TWebBrowserDesign.Notify: HResult;
begin
  Result := S_OK;
  if not FDocumentComplete then
    FDocumentComplete := FHTMLDocument2.readyState = 'complete'
  else if Assigned(FOnChange) then
    FOnChange();
end;

请注意注册变更接收器后对 _Release 的调用。这是为了“防止”标记容器持有对 TWebBrowserDesign 实例的强引用。这允许您使用 TWebBrowserDesign 实例的生命周期来控制设计模式:

type
  TForm1 = class(TForm)
    { ... }
  private
    FWebBrowserDesign: IInterface;
    { ... }
  end;

procedure TForm1.WebBrowser1DocumentComplete(ASender: TObject;
  const pDisp: IDispatch; const URL: OleVariant);
begin
  { enter design mode }
  FWebBrowserDesign := TWebBrowserDesign.Create(WebBrowser1, procedure
    begin
      ButtonSave.Enabled := True;
    end);
end;

procedure TForm1.ButtonSave(Sender: TObject);
begin
  { exit design mode }
  FWebBrowserDesign := nil;
  ButtonSave.Enabled := False;
end;

或者，您可以将更改接收器实现为组件。

type
  TWebBrowserDesign = class(TComponent, IHTMLChangeSink)
  private
    FDirtyRangeCookie: LongWord;
    FDocumentComplete: Boolean;
    FHTMLDocument2: IHTMLDocument2;
    FMarkupContainer2: IMarkupContainer2;
    FOnChange: TNotifyEvent;
    FWebBrowser: TWebBrowser;
    procedure EnterDesignMode;
    procedure ExitDesignMode;
    function GetActive: Boolean;
    procedure SetActive(const Value: Boolean);
    procedure SetWebBrowser(const Value: TWebBrowser);
    { IHTMLChangeSink }
    function Notify: HResult; stdcall;
  protected
    procedure Notification(AComponent: TComponent; Operation: TOperation); override;
  public
    destructor Destroy; override;
  published
    property Active: Boolean read GetActive write SetActive;
    property OnChange: TNotifyEvent read FOnChange write FOnChange;
    property WebBrowser: TWebBrowser read FWebBrowser write SetWebBrowser;
  end;

destructor TWebBrowserDesign.Destroy;
begin
  ExitDesignMode;
  inherited;
end;

procedure TWebBrowserDesign.EnterDesignMode;
begin
  if not Assigned(FWebBrowser) then
    raise Exception.Create('Web browser control missing.');
  if not Supports(FWebBrowser.Document, IHTMLDocument2, FHTMLDocument2) then
    raise Exception.Create('No HTML document loaded.');
  try
    FHTMLDocument2.designMode := DesignMode[True];
    if Supports(FWebBrowser.Document, IMarkupContainer2, FMarkupContainer2) then
    begin
      if FMarkupContainer2.RegisterForDirtyRange(Self, FDirtyRangeCookie) <> S_OK then
        FDirtyRangeCookie := 0;
    end;
  except
    ExitDesignMode;
    raise;
  end;
end;

procedure TWebBrowserDesign.ExitDesignMode;
begin
  if Assigned(FMarkupContainer2) then
  begin
    if FDirtyRangeCookie <> 0 then
    begin
      FMarkupContainer2.UnRegisterForDirtyRange(FDirtyRangeCookie);
      FDirtyRangeCookie := 0;
    end;
    FMarkupContainer2 := nil;
  end;
  if Assigned(FHTMLDocument2) then
  begin
    FHTMLDocument2.designMode := DesignMode[False];
    if not (csDestroying in ComponentState) then
      FHTMLDocument2 := nil; { causes AV when its hosting TWebBrowser component is destroying; I didn't dig into details }
  end;
  FDocumentComplete := False;
end;

function TWebBrowserDesign.GetActive: Boolean;
begin
  Result := Assigned(FHTMLDocument2);
end;

procedure TWebBrowserDesign.Notification(AComponent: TComponent;
  Operation: TOperation);
begin
  inherited;
  if (Operation = opRemove) and (AComponent = FWebBrowser) then
    WebBrowser := nil;
end;

function TWebBrowserDesign.Notify: HResult;
begin
  Result := S_OK;
  if not FDocumentComplete then
    FDocumentComplete := FHTMLDocument2.readyState = 'complete'
  else if Assigned(FOnChange) then
    FOnChange(Self);
end;

procedure TWebBrowserDesign.SetActive(const Value: Boolean);
begin
  if Active <> Value then
  begin
    if Value then
      EnterDesignMode
    else
      ExitDesignMode;
  end;
end;

procedure TWebBrowserDesign.SetWebBrowser(const Value: TWebBrowser);
begin
  if Assigned(FWebBrowser) then
  begin
    ExitDesignMode;
    FWebBrowser.RemoveFreeNotification(Self);
  end;
  FWebBrowser := Value;
  if Assigned(FWebBrowser) then
    FWebBrowser.FreeNotification(Self);
end;

如果您将此类组件放入设计时包中并在 IDE 中注册，那么您将能够将此组件与 TWebBrowser 链接并分配 OnChange 表单设计器中的事件处理程序。在代码中使用Active属性进入/退出设计模式。

type
  TForm1 = class(TForm)
    { ... }
    WebBrowserDesign1: TWebBrowserDesign;
    { ... }
  end;

procedure WebBrowserDesign1Change(Sender: TObject);
begin
  ButtonSave.Enabled := True;
end;

procedure TForm1.WebBrowser1DocumentComplete(ASender: TObject;
  const pDisp: IDispatch; const URL: OleVariant);
begin
  { enter design mode }
  WebBrowserDesign1.Active := True;
end;

procedure TForm1.ButtonSave(Sender: TObject);
begin
  { exit design mode }
  WebBrowserDesign1.Active := False;
  ButtonSave.Enabled := False;
end;

注意:关于 C#/WinForms 也提出了类似的问题 - How do I detect when the content of a WebBrowser control has changed (in design mode)?

最后一点:我不相信更改后启用保存按钮是最好的用户体验设计。如果您认为上面的代码值得实现您的目标，那么就继续吧。这只是概念证明，代码尚未经过彻底测试。需要您自担风险使用它。

关于delphi - 检测可编辑 TWebBrowser 中的更改，我们在Stack Overflow上找到一个类似的问题： https://stackoverflow.com/questions/62344444/

上一篇：reactjs - 无法从 gatsby-config.js 多个查询 GrahQL 读取 siteMetadata 对象 - Gatsby ReactJS

下一篇：opencl - 我应该如何查看全局和本地工作规模

相关文章：

delphi - 如何获取列出的网页的所有元素Id？

c - x86-64 上的 Delphi SizeOf(NativeInt) 与 C sizeof(int)。为什么大小不同？

windows - Delphi:自定义窗口菜单:需要 Msg.CmdType 和 $FFF0 说明

delphi - 如何使组件编辑器在双击时执行原始处理程序？

Delphi，将 cookie 集成或组合或加入到互联网浏览器

delphi - 当 Twebbrowser 控件不可见时如何强制加载页面

delphi - Delphi:重载不会调用重写的虚拟构造函数后代

delphi - 如何正确处理字符串数组以防止内存泄漏？

Delphi asm 到 purepascal

delphi - 如何在兼容的方法指针之间进行转换？

©2024 IT工具网  联系我们