perl - 使用 Spreadsheet::WriteExcel 读取文件并将段写入 Excel

Question

作为我上一个问题的扩展，我需要将输入文件从第一行提取到空行，然后按顺序将输出粘贴到 xls 的单个单元格中。例如，“E: sda E: qwe E: ass”将打印在 A1 单元格中，NA 将打印在 A3 单元格中，“E: sda E: qwe E: ass”将打印在单元格 A5 中。输入文件的模式会改变，但每个段由一个空行分隔。下面的代码片段只能将整个文件内容打印到一个单元格中。
输入文件:

E: sda
E: qwe
E: sss

NA

E: sda
E: qwe
E: sss

NA

NA

E: xx
E: xxxs

NA

代码:

use strict;
use warnings;
use Spreadsheet::WriteExcel;
my $filename = 'all_in_one.txt';
my $workbook = Spreadsheet::WriteExcel->new("sad.xls");
my $wrksheet = $workbook->add_worksheet("summary");


    for (my $i = 9) {
            my $result1 = read_out_your_file_misc($filename,"\n");
            $wrksheet->write($i, 1, [$result1]);
            $i = $i + 2;
        
    }

sub read_out_your_file_misc {
    my $filename = shift or die "ERROR: read_out_your_file_misc needs a filename";
    my $delim = shift || ',';        # make the default delimiter a comma

    open my $fhh, '<', $filename or die "ERROR: $filename: $!";
    my @content_of_file = <$fhh>;    # read the whole file at once
    close $fhh;
    chomp @content_of_file;          # chomp the complete array

    if(wantarray) {    # return an array if that's wanted
        @content_of_file;
    } else {           # else return it as a scalar with $delim between elements
        join($delim, @content_of_file);
    }
}

Answer 1

您正在将输入文件的每一行读入数组中的一个单独元素。但是，您不想这样做。
如果您更改 input record separator变量 ( $/ ) 使用段落模式，您可以将每组行放入每隔一行的单独单元格中:

use strict;
use warnings;
use Spreadsheet::WriteExcel;

my $filename = 'all_in_one.txt';
local $/ = ""; # paragraph mode
open my $fhh, '<', $filename or die "ERROR: $filename: $!";
my @content_of_file = <$fhh>;    # read the whole file at once
close $fhh;
chomp @content_of_file;          # chomp the complete array

my $workbook = Spreadsheet::WriteExcel->new("sad.xls");
my $wrksheet = $workbook->add_worksheet("summary");
for my $i (0 .. $#content_of_file) {
    $wrksheet->write(2*$i, 1, $content_of_file[$i]);
}

您在一个单元格中获取整个文件的原因是您 join将所有行重新组合成一个标量变量 ( $result1 )，然后将该单个值写入一个单元格。另外，for loop 有点奇怪，它只循环一次。