我是 xslt 新手，经过多次尝试后无法解决以下问题。
我有一个 xml 数据文件，其中包含我无法更改的数据。例如下面的简单 xml 文件:
<?xml version="1.0" encoding="UTF-8"?>
<sales>
<sale>
<year>2012</year>
<amount>200</amount>
</sale>
<sale>
<year>2012</year>
<amount>180</amount>
</sale>
<sale>
<year>2010</year>
<amount>120</amount>
</sale>
</sales>
我想按年份对销售数据进行分组并对金额进行求和，这样我就可以获得每年的总金额，我可以这样做。
xml 文件中有 2012 年和 2010 年的数据，但没有 2011 年的数据。
我希望 2011 年的输出为 0，这样我就有 2010、2011 和 2012 年所有年份的输出。
我实际上将使用 xls 来生成图表，但在这个简单的示例中我使用 html 作为输出。我正在使用 Altova XMLSpy 来测试 xls 并查看生成的 html 文档。
这是我编写的简单 xls 代码，用于对 HTML 中的数据进行分组和显示:
<?xml version="1.0" encoding="UTF-8"?>
<xsl:stylesheet version="2.0" xmlns:xsl="http://www.w3.org/1999/XSL/Transform">
<xsl:template match="/">
<html>
<body>
<table border="1">
<tr>
<th>Year</th>
<th>Amount</th>
</tr>
<xsl:for-each-group select="sales/sale" group-by="year">
<xsl:sort select="year"/>
<tr>
<td><xsl:value-of select="year"/></td>
<td><xsl:value-of select="sum(current-group()/amount)"/></td>
</tr>
</xsl:for-each-group>
</table>
</body>
</html>
</xsl:template>
</xsl:stylesheet>
当我使用 Altova XMLSpy 针对 xml 文件运行此命令时，我在浏览器窗口中看到以下内容。一个有 3 行的小表，一个带有标题的标题，然后是 2 行数据，一行是 2012 年的，另一行是 2010 年的。作为 stackoverflow 的新用户，我还不能使用图像，所以这里是可以查看的源 html 代码在浏览器中。
<html>
<body>
<table border="1">
<tr>
<th>Year</th>
<th>Amount</th>
</tr>
<tr>
<td>2010</td>
<td>120</td>
</tr>
<tr>
<td>2012</td>
<td>380</td>
</tr>
</table>
</body>
</html>
我可以使用 xls 创建 2011 年的行(金额为 0)，以便我的输出显示 2010、2011 和 2012 年范围内的数据吗？
请注意，我无法在 xls 中对年份进行硬编码，我必须导出缺少的年份。
通常我会确保源 xml 文件包含所需的所有数据，但在本例中这是不可能的。
感谢任何帮助。
亲切的问候
细胞
最佳答案
这是一个解决方案:
<?xml version="1.0" encoding="UTF-8"?>
<xsl:stylesheet version="2.0" xmlns:xsl="http://www.w3.org/1999/XSL/Transform"
xmlns:xs="http://www.w3.org/2001/XMLSchema"
exclude-result-prefixes="xs">
<xsl:output method="html" indent="yes"/>
<xsl:key name="sale-by-year" match="sale" use="xs:integer(year)"/>
<xsl:template match="/">
<html>
<body>
<table border="1">
<tr>
<th>Year</th>
<th>Amount</th>
</tr>
<xsl:variable name="doc" select="/"/>
<xsl:for-each select="min(sales/sale/year/xs:integer(.)) to max(sales/sale/year/xs:integer(.))">
<xsl:variable name="sales-of-year" select="key('sale-by-year', ., $doc)"/>
<tr>
<td>
<xsl:value-of select="."/>
</td>
<td>
<!-- <xsl:value-of select="if ($sales-of-year) then sum($sales-of-year/amount) else 0"/> -->
<xsl:value-of select="sum($sales-of-year/amount)"/>
</td>
</tr>
</xsl:for-each>
</table>
</body>
</html>
</xsl:template>
</xsl:stylesheet>
关于xslt - 当某些日期不在源 xml 中时，如何输出一系列日期的数据，我们在Stack Overflow上找到一个类似的问题： https://stackoverflow.com/questions/13899651/