我一直在尝试批量制作一款石头剪刀布游戏。到目前为止,脚本运行,我可以让它与自己对战或与我对战(我需要将 B 变量从/A 和随机数更改为/P 并接受用户输入)。
问题是,经过几轮(每次的数量不同)后,脚本崩溃了,我没有时间阅读最后一行文本(这将帮助我找到错误)。我尝试过打开和关闭 ECHO,还尝试从不同的 DOS 窗口运行“RPS.bat >> log.txt”(选择正确的目录)。这确实记录了所有内容,直到崩溃,并且也没有得到最后一行。
我已经查了好几遍了,但找不到错误......:(
我用 PHP 制作了同样的游戏,目前没有错误......(我知道这是一种完全不同的语言)
这是我的脚本:
@ECHO OFF
:TOP
SET /A AWON=0
SET /A BWON=0
SET /A NWON=0
:GAME
SET /A A=%RANDOM% %% 3 + 1
SET /P B=Number from 1 to 3
IF %A% EQU 1 (
GOTO A1
) ELSE IF %A% EQU 2 (
GOTO A2
) ELSE IF %A% EQU 3 (
GOTO A3
) ELSE (
GOTO GAME
)
:A1
IF %B% EQU 1 (
GOTO DRAW
) ELSE IF %B% EQU 2 (
GOTO BWIN
) ELSE IF %B% EQU 3 (
GOTO AWIN
) ELSE (
GOTO GAME
)
:A2
IF %B% EQU 1 (
GOTO ARAW
) ELSE IF %B% EQU 2 (
GOTO DRAW
) ELSE IF %B% EQU 3 (
GOTO BWIN
) ELSE (
GOTO GAME
)
:A3
IF %B% EQU 1 (
GOTO BWIN
) ELSE IF %B% EQU 2 (
GOTO AWIN
) ELSE IF %B% EQU 3 (
GOTO DRAW
) ELSE (
GOTO GAME
)
:AWIN
SET /A AWON=%AWON% + 1
ECHO -------------------------------------------------------------------------------
ECHO A won this round!
ECHO ---
ECHO A won: %AWON%
ECHO B won: %BWON%
ECHO Draw: %NWON%
PAUSE
GOTO GAME
:BWIN
SET /A BWON=%BWON% + 1
ECHO -------------------------------------------------------------------------------
ECHO B won this round!
ECHO ---
ECHO A won: %AWON%
ECHO B won: %BWON%
ECHO Draw: %NWON%
PAUSE
GOTO GAME
:DRAW
SET /A NWON=%NWON% + 1
ECHO -------------------------------------------------------------------------------
ECHO This round was a draw!
ECHO ---
ECHO A won: %AWON%
ECHO B won: %BWON%
ECHO Draw: %NWON%
PAUSE
GOTO GAME
感谢格雷帮助我解决了我的愚蠢错误^^
也感谢您提供的脚本,但如果我没有遗漏任何内容,那么它就不太正确。
@ECHO OFF
:GAME
SET /P A=A:
SET /P B=B:
SET /A WINNER=(%A%-%B%) %% 3
ECHO %A% - %B% = %WINNER%
IF %WINNER% EQU 1 (
echo A WON!
) ELSE (
IF %WINNER% EQU 0 (
echo DRAW!
) ELSE (
echo B WON!
))
PAUSE
GOTO GAME
运行该脚本(格雷脚本的“缩短”版本)。使用像我的“表”中那样的变量,您可以看到,通过选择 1(摇滚),A 无法获胜(A=1 vs B=3 应该是:A 获胜)。您知道如何解决这个问题吗?我猜是“硬编码”?当 A=1 和 B=3 时的解决方案是最好的? (我的意思是,当这些值是时,“正常”脚本不适用,但特殊代码会给出结果)。
在我的表格中,如果最后一个符号是“+”,则脚本给出正确答案,如果最后一个符号是“-”,则脚本给出错误答案。
ITEM VALUE
ROCK 1
PAPER 2
SCISSORS 3
A - B = WINNER
1 - 1 = 0 DRAW +
1 - 2 = -1 B WON +
1 - 3 = -2 A WON -
2 - 1 = 1 A WON +
2 - 2 = 0 DRAW +
2 - 3 = -1 B WON +
3 - 1 = 2 B WON +
3 - 2 = 1 A WON +
3 - 3 = 0 DRAW +
此外,如果您对如何保持脚本更加整洁并使用更少的代码行来完成相同的工作有任何建议,我很乐意倾听!
提前致谢! - 埃斯彭
最佳答案
您的错误可能是:
The system cannot find the batch label specified - ARAW
这是因为您的 A2
标签中有 GOTO ARAW
,而看起来您打算执行 GOTO AWIN
奖励:作为确定获胜者的更“聪明”的方式(肯定可以进一步改进)
@echo off
rem rock:1; paper:2; scissors:3
:GAME
SET /A CPU=%RANDOM% %% 3 + 1
SET /P PLAYER=Number from 1 to 3
cls
echo %CPU% vs %PLAYER%
rem set /A WINNER=(%CPU%-%PLAYER%) %% 3 //this does not work with batch - my mistake
SET /A WINNER=(%CPU% - %PLAYER% + 3) %% 3
IF %WINNER% EQU 1 (
echo CPU WON!
) ELSE (
IF %WINNER% EQU 0 (
echo DRAW!
) ELSE (
echo YOU WON!
))
GOTO GAME
最后,这是一个打印“石头”、“布”和“剪刀”的东西,使其更......有趣
@echo off
rem rock:1; paper:2; scissors:3
:GAME
SET /A CPU=%RANDOM% %% 3 + 1
SET /P PLAYER=Number from 1 to 3
goto CPUTYPE
:TYPE1
goto PLAYERTYPE
:TYPE2
cls
echo CPU:%CPUT% vs YOU:%PLAYERT%
rem set /A WINNER=(%CPU%-%PLAYER%) %% 3 //this does not work with batch - my mistake
SET /A WINNER=(%CPU% - %PLAYER% + 3) %% 3
IF %WINNER% EQU 1 (
echo CPU WON!
) ELSE (
IF %WINNER% EQU 0 (
echo DRAW!
) ELSE (
echo YOU WON!
))
GOTO GAME
:CPUTYPE
IF %CPU% EQU 1 (
SET CPUT="ROCK"
) ELSE (
IF %CPU% EQU 2 (
SET CPUT="PAPER"
) ELSE (
SET CPUT="SCISSORS"
))
GOTO TYPE1
:PLAYERTYPE
IF %PLAYER% EQU 1 (
SET PLAYERT="ROCK"
) ELSE (
IF %PLAYER% EQU 2 (
SET PLAYERT="PAPER"
) ELSE (
SET PLAYERT="SCISSORS"
))
GOTO TYPE2
基于提问者的 PvP 版本更新版本(固定模块
@ECHO OFF
:GAME
SET /P A=A:
SET /P B=B:
SET /A WINNER=(%A% - %B% + 3) %% 3
ECHO W= %WINNER%
IF %WINNER% EQU 1 (
echo A WON!
) ELSE (
IF %WINNER% EQU 0 (
echo DRAW!
) ELSE (
echo B WON!
))
PAUSE
GOTO GAME
SET/A WINNER=(%CPU% - %PLAYER% + 3) %% 3
的解释:
2拍1、3拍2、1拍3。如果你把它画出来,它是一种圆形。我们使用 %
或模运算符来做到这一点。如果您使用整数除法除以该数字,则模运算符基本上会给出余数。
这里是 1 到 6 mod 3,答案以粗体显示。
1/3 = 0 雷姆 1
2/3 = 0 雷姆 2
3/3 = 1 雷姆 0
4/3 = 1 雷姆 1
5/3 = 1 雷姆2
6/3 = 2 雷姆 0
请注意结果为何总是 < 3 且 > 0?我们利用这种机制来模仿石头剪刀布的循环行为。您可能还注意到我在这些示例中没有执行+3。添加+3是因为微软选择实现模数的方式,当你有负数时它会做奇怪的事情(这就是我们修复你发现的错误的方式)。我假设它使用了一个模数,就像我习惯的那样,符号不会改变结果。基本上,它只是将运算上移 3,使其永远不会为负。您可以在这里阅读有关此类事情的更多信息:circular buffer 。我喜欢例子,所以这里有一些可能有帮助的东西。
关系:
1v1 -> (1 - 1 + 3) % 3 -> 3 % 3 -> 1 rem 0
2v2 -> (2 - 2 + 3) % 3 -> 3 % 3 -> 1 rem 0
3v3 -> (3 - 3 + 3) % 3 -> 3 % 3 -> 1 rem 0
玩家 1 获胜
1v3 -> (1 - 3 + 3) % 3 -> 1 % 3 -> 0 rem 1
2v1 -> (2 - 1 + 3) % 3 -> 4 % 3 -> 1 rem 1
3v2 -> (3 - 2 + 3) % 3 -> 4 % 3 -> 1 rem 1
玩家 2 获胜
1v2 -> (1 - 2 + 3) % 3 -> 2 % 3 -> 0 rem 2
2v3 -> (2 - 3 + 3) % 3 -> 2 % 3 -> 0 rem 2
3v1 -> (3 - 1 + 3) % 3 -> 5 % 3 -> 1 rem 2
这里的模式是所有余数(模运算符的结果)全部匹配。多么方便啊!现在我们只需将该案例与 if 语句相匹配,我们就知道谁赢得了每场比赛。
关于if-statement - BATCH - RPS - 石头、剪刀、布 - 几轮后继续失败,我们在Stack Overflow上找到一个类似的问题: https://stackoverflow.com/questions/17621743/