我有这些数据:
2019-08-28,384
2019-08-29,394
2019-08-30,406
2019-08-31,424
2019-09-01,439
2019-09-02,454
2019-09-03,484
还有 gnuplot 脚本:
set title "test"
set terminal png truecolor size 960,720 background rgb "#eff1f0"
set output "/home/tbenedet/Desktop/GNUPLOT\ AIX/test.png"
set grid
set style line 1 \
linecolor rgb '#0060ad' \
linetype 1 linewidth 2 \
pointtype 7 pointsize 1.5
set offsets 0.5,0.5,0,0.5
set datafile separator ","
plot "df_output.txt" using 2:xtic(1) with linespoints linestyle 1
我想画一条这样的趋势线:
但我的数学很差,我不知道如何使用 gnuplot 来做到这一点......有人可以告诉我吗?
最佳答案
假设您的数据由一条直线描述,您可以使用定义这样的方程并使用fit
命令。
set title "test"
set terminal pngcairo size 700,600
set output "test.png"
set grid
set style line 1 \
linecolor rgb '#0060ad' \
linetype 1 linewidth 2 \
pointtype 7 pointsize 1.5
set offsets 0.5,0.5,0,0.5
set datafile separator ","
set key Left left reverse
# The equation
f(x) = a*x + b
# The fit
fit f(x) "df_output.txt" u 0:2 via a,b
set xtics rotate by 45 right
plot \
"df_output.txt" u 2:xtic(1) w p ls -1 pt 7 title "data points",\
f(x) w l lc "red" title "trendline"
结果
关于gnuplot - 如何使用 Gnuplot 4.6 在我的图表中追踪趋势线?,我们在Stack Overflow上找到一个类似的问题: https://stackoverflow.com/questions/57806677/