regex - 正则表达式只匹配 n 次

Question

如果我有线条:

1. 'aslkdfjcacttlaksdjcacttlaksjdfcacttlskjdf'
2. 'asfdcacttaskdfjcacttklasdjf'
3. 'cksjdfcacttlkasdjf'

我想通过重复子单元 (cactt) 出现的次数来匹配它们。换句话说，如果我要求 n 次重复，我希望匹配包含 n 个且仅包含 n 个模式实例。

我最初的尝试是在 perl 中实现的，看起来像这样:

    sub MATCHER {
        print "matches with $_ CACTT's\n";
        my $pattern = "^(.*?CACTT.+?){$_}(?!.*?CACTT).*\$";
        my @grep_matches = grep(/$pattern/, @matching);
        print "$_\n" for @grep_matches;
        my @copy = @grep_matches;
        my $squashed = @copy;
        print "number of rows total: $squashed\n";
    }

    for (2...6) {
        MATCHER($_);
    }

注意事项:

@matching contains the strings from 1, 2, and 3 in an array. the for loop is set from integers 2-6 because I have a separate regex that works to forbid duplicate occurrences of the pattern.

这个循环几乎可以工作，除了 n=​​2 时，会返回包含 3 次“cactt”模式的匹配项。事实上，对于任何包含 n+1 个匹配项(其中 n>=2)的字符串，匹配项也会返回出现 n+1 次的行。我虽然消极的前瞻可以防止perl中的这种行为。如果有人能给我一些想法，我将不胜感激。

另外，我曾想过每行计数并按计数分隔它们；我不喜欢这种方法，因为它需要两个步骤才能完成我想要的。

我可以接受:

    foreach (@matches) { $_ =~ /$pattern/; push(@selected_by_n, $1);}

正则表达式看起来应该是相似的，但在实践中无论出于何种原因，结果差异很大。

提前致谢!

Answer 1

你的代码有点奇怪。这个正则表达式

my $pattern = "^(.*?CACTT.+?){$_}(?!.*?CACTT).*\$";

..尝试匹配字符串 ^ 的第一个开头，然后是任何字符 .*? 的最小匹配，然后是您的序列 CACTT，后跟一个最小匹配(但与 .*? 略有不同).+?。你想匹配这些 $_ 次。您假设调用 sub 时 $_ 是正确的(这很糟糕)。然后，您有一个前瞻性假设，希望确保没有任何字符 .*? 的最小匹配，然后是您的序列，然后是任何长度的任何字符，然后是行尾 $.

首先，这总是多余的:^.*。行首 anchor 后跟任意字符任意次数。这实际上使 anchor 无用。 .*$ 也是如此。为什么？因为任何将发生的匹配，无论如何都会在第一个可能的时间发生。 .*$ 与空字符串的作用完全相同:任何东西。

例如:正则表达式 /^.*?foo.*?$/ 与 /foo/ 完全匹配。 (不包括与包含换行符的字符串进行多行匹配的情况)。

在你的情况下，如果你想计算一个字符串在一个字符串中出现的次数，你可以像这样匹配它们:

my $count = () = $str =~ /CACTT/gi;

这段代码:

my @copy = @grep_matches;
my $squashed = @copy;

完全是多余的。你可以做 my $squashed = @grep_matches。首先复制数组几乎没有意义。

这段代码:

MATCHER($_);

与此相同:MATCHER("foo") 或 MATCHER(3.1415926536)。您没有使用 subroutine 参数，而是忽略了它，并依赖于 $_ 是全局且在 sub 内可见的事实。你想做的是

sub MATCHER {
    my $number = shift;   # shift argument from @_

现在你已经封装了代码，一切都很好。

我假设你想要做的是计算字符串中子字符串的出现次数，然后报告它们。我会做这样的事情

use strict;
use warnings;
use Data::Dumper;

my %data;
while (<DATA>) {
    chomp;
    my $count = () = /cactt/gi;      # count number of matches
    push @{ $data{$count} }, $_;     # store count and original
}

print Dumper \%data;

__DATA__
aslkdfjcacttlaksdjcacttlaksjdfcacttlskjdf
asfdcacttaskdfjcacttklasdjf
cksjdfcacttlkasdjf

这将打印出来

$VAR1 = {
          '2' => [
                   'asfdcacttaskdfjcacttklasdjf'
                 ],
          '3' => [
                   'aslkdfjcacttlaksdjcacttlaksjdfcacttlskjdf'
                 ],
          '1' => [
                   'cksjdfcacttlkasdjf'
                 ]
        };

这只是为了演示如何创建数据结构。您现在可以按匹配顺序访问字符串。例如:

for (@$data{3}) {    # print strings with 3 matches
    print;
}