perl - Perl 程序可以知道 __DATA__ 开始的行号吗？

Question

有没有办法在 处获取行号(也可能是文件名) __数据__ token 被编码？或者其他一些方法来知道原始源文件中的实际行号，从 DATA 文件句柄读取的一行数据来自哪里？

请注意 $.从 DATA 读取时从 1 开始计数文件句柄。所以如果__DATA__的行号 token 已添加到 $.这将是我正在寻找的。

例如:

#!/usr/bin/perl
while (<DATA>) {
  my $n = $. + WHAT??;
  die "Invalid data at line $n\n" if /bad/;
}

__DATA__
something good
something bad

我希望这表示“第 9 行的数据无效”，而不是“第 2 行”(如果 $. 单独使用，您会得到)。

Answer 1

Perl 会跟踪创建每个符号的文件和行。符号通常在解析器/编译器第一次遇到它时创建。但如果 __DATA__之前遇到过 DATA否则创建，这将创建符号。我们可以利用这一点来设置与 DATA 中的文件句柄相关联的行号。 .
对于 Package::DATA 的情况 handle 是不是 用于 Package.pm本身，__DATA__ 的行号 token 可以通过 B::GV->LINE 获得在 DATA处理:

$ cat Foo.pm
package Foo;

1;
__DATA__
good
bad

$ perl -I. -MFoo -MB -e '
   my $ln = B::svref_2object(\*Foo::DATA)->LINE;
   warn "__DATA__ at line $ln\n";
   Foo::DATA->input_line_number($ln);
   while(<Foo::DATA>){ die "no good" unless /good/ }
'
__DATA__ at line 4
no good at -e line 1, <DATA> line 6.

在DATA的情况下文件本身引用了句柄，一个可能的组合是使用 @INC hook :

$ cat DH.pm
package DH;

unshift @INC, sub {
        my ($sub, $fname) = @_;
        for(@INC){
                if(open my $fh, '<', my $fpath = "$_/$fname"){
                        $INC{$fname} = $fpath;
                        return \'', $fh, sub {
                                our (%ln, %pos);
                                if($_){ $pos{$fname} += length; ++$ln{$fname} }
                        }
                }
        }
};

$ cat Bar.pm
package Bar;

print while <DATA>;

1;
__DATA__
good
bad

$ perl -I. -MDH -MBar -e '
    my $fn = "Bar.pm";
    warn "__DATA__ at line $DH::ln{$fn} pos $DH::pos{$fn}\n";
    seek Bar::DATA, $DH::pos{$fn}, 0;
    Bar::DATA->input_line_number($DH::ln{$fn});
    while (<Bar::DATA>){ die "no good" unless /good/ }
'
good
bad
__DATA__ at line 6 pos 47
no good at -e line 6, <DATA> line 8.

只是为了完成，在您确实可以控制文件的情况下，所有这些都可以轻松完成:

print "$.: $_" while <DATA>;
BEGIN { our $ln = __LINE__ + 1; DATA->input_line_number($ln) }
__DATA__
...

您也可以使用第一个 B::GV解决方案，前提是您引用了 DATA通过 eval 处理:

use B;
my ($ln, $data) = eval q{B::svref_2object(\*DATA)->LINE, \*DATA}; die $@ if $@;
$data->input_line_number($ln);
print "$.: $_" while <$data>;
__DATA__
...

这些解决方案都没有假设源文件是可查找的(除非您想多次阅读 DATA，就像我在第二个示例中所做的那样)，或者尝试重新解析您的文件等。