windows - findstr命令变量在for循环批处理脚本中的路径中扩展(Windows，批处理脚本)

Question

echo off
set "MasterFolder=C:\Users\Development\test_folder"
SetLocal EnableDelayedexpansion
@FOR /f "delims=" %%f IN ('dir /b /s "%MasterFolder%\*.txt"') DO (
    set /a "idx+=1"
    set "FileName[!idx!]=%%~nxf"
    set "FilePath[!idx!]=%%~dpFf"
)

for /L %%i in (1,1,%idx%) do (
    echo [%%i] "!FileName[%%i]!"

    set "loc=%MasterFolder%\!FileName[%%i]!"
    echo path: %MasterFolder%\!FileName[%%i]!
    echo loc: !loc!
    FOR /F "tokens=1,2 delims=:" %%1 in ('findstr /o "^" "%MasterFolder%\test_1.txt"') DO (
        set new_pos=%%1
        echo new_pos !new_pos!
    )
)

上面的代码可以工作，但是下面的代码不起作用。

echo off
... 
FOR /F "tokens=1,2 delims=:" %%1 in ('findstr /o "^" "%MasterFolder%\!FileName[%%i]!"') DO (
        set new_pos=%%1
        echo new_pos !new_pos!
    )
)

echo off
...
    FOR /F "tokens=1,2 delims=:" %%1 in ('findstr /o "^" "!loc!"') DO (
        set new_pos=%%1
        echo new_pos !new_pos!
    )
)

我所做的就是将 test_1.txt 替换为 !FileName[%%i]!，或者使用新变量并将全部替换为 "!loc!"。

但是最后两个代码不起作用，我需要这种方式，因为它通过第一个 for 循环自动获取文件夹中的文件名。

我猜想 findstr 或变量扩展顺序有错误，但我很难弄清楚。

Answer 1

很明显!

使用 !file... 时，在行中引入感叹号。

这会触发phase 5 (delayed epxansion phase) of the parser .
在该阶段，变量被扩展并且插入符用于转义下一个字符，独立于它们所在的位置(带引号或不带引号)!

因此，您的搜索字符串 "^" 将转换为 ""。

只需将插入符号加倍即可 findstr/o "^^"!File...

感叹号效果有点出乎意料

setlocal EnableDelayedExpansion
echo One Caret "^"
echo One Caret "^" and a bang ^^!

输出

One Caret "^"
One Caret "" and a bang !