stata - 使用移动时间窗口计算运行总和

Question

我的数据

我正在处理以下格式的拼写数据集:

cls
clear all
set more off

input id spellnr  str7 bdate_str  str7 edate_str  employed
       1    1         2008m1          2008m9          1  
       1    2        2008m12          2009m8          0   
       1    3        2009m11          2010m9          1  
       1    4        2010m10          2011m9          0  
       ///
       2    1         2007m4         2009m12          1
       2    2         2010m4          2011m4          1
       2    3         2011m6          2011m8          0
end

* translate to Stata monthly dates
gen bdate = monthly(bdate_str,"YM")
gen edate = monthly(edate_str,"YM")
drop *_str
format %tm bdate edate

list, sepby(id)

对应于:

     +---------------------------------------------+
     | id   spellnr   employed     bdate     edate |
     |---------------------------------------------|
  1. |  1         1          1    2008m1    2008m9 |
  2. |  1         2          0   2008m12    2009m8 |
  3. |  1         3          1   2009m11    2010m9 |
  4. |  1         4          0   2010m10    2011m9 |
     |---------------------------------------------|
  5. |  2         1          1    2007m4   2009m12 |
  6. |  2         2          1    2010m4    2011m4 |
  7. |  2         3          0    2011m6    2011m8 |
     +---------------------------------------------+

这里给定的人 (id) 可以有两种类型的多个法术 (spellnr) (unempl: 1 表示失业；0 表示就业)。每个咒语的开始和结束日期分别由 bdate 和 edate 定义。

假设数据已经被清理过，并且没有法术重叠彼此。 但是，任何两个法术之间可能会有“缺失”的时期。 这是由上面的虚拟数据集捕获的。

我的问题:

对于每个失业期，我需要计算过去 6 个月、12 个月和 24 个月内在工作中花费的月数。

请注意，重要的是，每个 id 都可以入职和离职，并且应该考虑所有 过去的工作时间(不仅仅是最后一个)。

在我的示例中，这将导致以下所需的输出:

     +--------------------------------------------------------------+
     | id   spellnr   employed     bdate     edate   m6   m24   m48 |
     |--------------------------------------------------------------|
  1. |  1         1          1    2008m1    2008m9    .     .     . |
  2. |  1         2          0   2008m12    2009m8    4     9     9 |
  3. |  1         3          1   2009m11    2010m9    .     .     . |
  4. |  1         4          0   2010m10    2011m9    6    11    20 |
     |--------------------------------------------------------------|
  5. |  2         1          1    2007m4   2009m12    .     .     . |
  6. |  2         2          1    2010m4    2011m4    .     .     . |
  7. |  2         3          0    2011m6    2011m8    5    20    44 |
     +--------------------------------------------------------------+

我的(工作)尝试:

以下代码返回所需的结果。

* expand each spell to one observation per time unit (here "months"; works also for days)
expand edate-bdate+1
bysort id spellnr: gen spell_date = bdate + _n - 1
format %tm spell_date
list, sepby(id spellnr)

* fill-in empty months (not covered by spells)
xtset id spell_date, monthly 
tsfill

* compute cumulative time spent in employment and lagged values
bysort id (spell_date): gen cum_empl = sum(employed) if employed==1
bysort id (spell_date): replace cum_empl = cum_empl[_n-1] if cum_empl==.
bysort id (spell_date): gen lag_7  = L7.cum_empl  if employed==0  
bysort id (spell_date): gen lag_24 = L25.cum_empl if employed==0
bysort id (spell_date): gen lag_48 = L49.cum_empl if employed==0
qui replace lag_7=0  if lag_7==.  & employed==0  // fix computation for first spell of each "id" (if not enough time to go back with "L.")
qui replace lag_24=0 if lag_24==. & employed==0  
qui replace lag_48=0 if lag_48==. & employed==0  

* compute time spent in employment in the last 6, 24, 48 months, at the beginning of each unemployment spell
bysort id (spell_date): gen m6  = cum_empl - lag_7  if employed==0  
bysort id (spell_date): gen m24 = cum_empl - lag_24 if employed==0
bysort id (spell_date): gen m48 = cum_empl - lag_48 if employed==0
qui drop if (spellnr==.)
qui bysort id spellnr (spell_date): keep if _n == 1
drop spell_date cum_empl lag_*

list

这工作正常，但在使用(数百万)每日数据时变得非常低效。您能否建议任何不涉及扩展数据集的替代方法？

我上面所做的就是:

1. 我将数据扩展为每月一行；
2. 我用 -tsfill-
填充法术之间的“空白”
3. 我计算就业所花费的运行时间，并使用滞后运算符获得三个感兴趣的数量。

这与所做的一样 here ，在我发布的过去的问题中。然而，那里的工作示例不必要地复杂并且存在一些错误。

---

解决方案性能

我尝试了下面接受的答案中建议的不同方法(包括使用早期版本的答案中建议的 joinby)。为了创建更大的数据集，我使用了:

expand 500000
bysort id spellnr: gen new_id = _n
drop id 
rename new_id id

它创建了一个包含 500,000 个 ID 的数据集(总共 3,500,000 个法术)。 第一个解决方案在很大程度上主导了使用 joinby 或 rangejoin 的解决方案(另请参阅下面对已接受答案的评论)。

Answer 1

下面的代码可能会节省一些运行时间。

bys id (employed): gen tag = _n if !employed
sum tag, meanonly
local maxtag = `r(max)'

foreach i in 6 24 48 {
gen m`i' = .

    forval d = 1/`maxtag' {
    by id: gen x = 1 + min(bdate[`d'],edate) - max(bdate[`d']-`i',bdate) if employed
    egen y = total(x*(x>0)), by(id)
    replace m`i' = y if tag == `d'
    drop x y
    }
}
sort id bdate

同样的逻辑，连同-rangejoin- (ssc) 也值得一试。请在使用您的(大量)实际数据进行测试后提供一些反馈。

preserve
    keep if employed
    replace employed = 0
    tempfile em
    save `em'
restore

foreach i in 6 24 48 {
gen _bd = bdate - `i'
rangejoin edate _bd bdate using `em', by(id employed) p(_)

egen m`i' = total(_edate - max(_bd,_bdate)+1) if !employed, by(id bdate)
bys id bdate: keep if _n==1
drop _*
}