java - 库中的 generateReleaseBuildConfig 错误

Question

安卓工作室项目。我有两个库模块，它们都没有任何 Java。我试图抑制 BuildConfig 生成，因此也没有生成 Java。第一个的 gradle 文件如下:

apply plugin: 'com.android.library'

android {
    compileSdkVersion 26

    defaultConfig {
        minSdkVersion 3
        targetSdkVersion 26

        externalNativeBuild {
            ndkBuild {
                abiFilters "armeabi", "x86", "x86_64", "armeabi-v7a", "mips", "arm64-v8a"
                targets "pad", "gif"
            }
        }
    }

    buildTypes {
        release {
            minifyEnabled false
        }
        debug {
            jniDebuggable true
        }
    }

    externalNativeBuild {
        ndkBuild {
            path file("src/main/jni/Android.mk")
        }
    }
}

dependencies {}

afterEvaluate {
    generateReleaseBuildConfig.enabled = false
    generateDebugBuildConfig.enabled = false
}

对于另一个:

apply plugin: 'com.android.library'

android {
    compileSdkVersion 26

    defaultConfig {
        minSdkVersion 3
        targetSdkVersion 26

        externalNativeBuild {
            ndkBuild {
                abiFilters "armeabi", "x86", "x86_64", "armeabi-v7a", "mips", "arm64-v8a"
            }
        }
    }

    buildTypes {
        release {
            minifyEnabled false
        }
        debug {
            jniDebuggable true
        }
    }

    externalNativeBuild {
        ndkBuild {
            path file("src/main/jni/Android.mk")
        }
    }

    flavorDimensions 'Color'
    productFlavors {
        Blue {
            dimension "Color"
            externalNativeBuild {
                ndkBuild {
                    cppFlags "-DBLUE"
                }
            }
        }
        Red {
            dimension "Color"
            externalNativeBuild {
                ndkBuild {
                    cppFlags "-DRED"
                }
            }
        }
    }
}

dependencies {
    implementation project(':Foo')
}

afterEvaluate {
    generateReleaseBuildConfig.enabled = false
    generateDebugBuildConfig.enabled = false
}

第一个工作了一段时间，没问题。第二个，我今天刚刚创建，Gradle 同步失败:

A problem occurred configuring project ':LibBar'.

Could not get unknown property 'generateReleaseBuildConfig' for project ':LibBar' of type org.gradle.api.Project.

如果我注释掉该行，它会提示 generateDebugBuildConfig .

第二个模块取决于第一个模块，不确定是否重要。

两者都有一个 list ，只有 package .

我错过了什么？我已经尝试清理项目，使缓存无效。 Gradle 是最新的，Android Studio 也是最新的(刚刚更新)。

Answer 1

构建系统使用当前构建风格装饰步骤名称。所以应该改为:

afterEvaluate {
    generateBlueReleaseBuildConfig.enabled = false
    generateBlueDebugBuildConfig.enabled = false
    generateRedReleaseBuildConfig.enabled = false
    generateRedDebugBuildConfig.enabled = false
}