unit-testing - 使用 spock 在 Controller 中单元测试 session 变量

Question

我正在尝试使用 Grails Controller 中的单元测试在 Controller 中的方法中设置 session 变量，但它提示设置只读属性:

Cannot set readonly property: session for class: MyController

我有这样的事情:

class MyController {
   def settingSession = {
       session.var1 = "hello world!"
   }
}

这将是我的测试:

class MyControllerUnitTest extends ControllerSpec {
    def "My test with sessions"() {
       when:
            controller.settingSession()
       then:
            controller.session.var1 == "hello world!"
    }
}

我邀请我可能应该编写一个集成测试，但我想知道是否有可能在单元测试中这样做。

Answer 1

以下测试将通过 Grails 2.1.0

Controller :

// grails-app/controllers/demo/MyController.groovy
package demo

class MyController {

    def settingSession() {
        session.band = 'King Crimson'
    }
}

单元测试:

// test/unit/demo/MyControllerTests.groovy
package demo

import grails.test.mixin.*
import org.junit.*

@TestFor(MyController)
class MyControllerTests {

    void testSettingSession() {
        controller.settingSession()

        assert session.band == 'King Crimson'
    }
}

如果您使用 Spock:

// test/unit/demo/MyControllerSpec.groovy
package demo

import grails.test.mixin.*
import spock.lang.Specification

@TestFor(MyController)
class MyControllerSpec extends Specification {

    void 'test session'() {
        when:
        controller.settingSession()

        then:
        session.band == 'King Crimson'
    }
}