grails - 在grails中加密xls文件并下载

Question

我需要使用密码或加密功能的xls文件下载。

import org.apache.poi.hssf.usermodel.HSSFWorkbook
import com.emmanuelrosa.frostedsheets.* 

def downloadxls(){
 /*
  * Creates a workbook with Apache POI and decorates it
  * with Frosted Sheets.
  */
    response.setContentType('application/vnd.ms-excel')
    response.setHeader('Content-Disposition', 'Attachment;Filename="data.xls"')

    // response.setContentType("APPLICATION/OCTET-STREAM")
    //  response.setHeader('Content-Disposition', 'Attachment;Filename="archivo.buf"')

    def outputStream = response.getOutputStream()
    def workbook = new FrostedWorkbook(new HSSFWorkbook())

    workbook['Students'].with {
        append(['First Name', 'Last Name', 'Age'])
        append(['John', 'Doe', '20'])
        append(['Jane', 'Smith', '18'])
    }

    workbook['Courses'].with {
        append(['Course Name', 'Number of Units'])
        append(['Algebra', 3])
        append(['English Grammar', 5])
    }
   /*
   * workbook is an instance of FrostedWorkbook, 
   * which implements the Workbook interface.
   * The writeProtectWorkbook() method is provided
   * by HSSFWorkbook (it's not in the interface).
   * FrostedWorkbook.workbook is the decorated HSSFWorkbook
   */

    workbook.workbook.writeProtectWorkbook('password', 'user')

    workbook.write(response.outputStream)
    outputStream << workbook

    outputStream.flush()

文件下载代码。使用此代码段，我可以下载.xls文件，但是即使您添加了所有数据，也仍未加密。

    outputStream.close()

}

问题是您下载的文件未加密。

Answer 1

您正在尝试使用两个库来创建Excel工作簿:JXL和Apache POI。他们彼此之间一无所知。因此，JXL忽略了密码。
Excel工作簿密码保护
加密和密码保护之间有区别。两者都使用密码，但是密码保护不会而不是加密文件。该文件仍可以读取，但不能修改。
这是一个示例，显示如何用密码保护工作簿。我正在使用Frosted Sheets库，它是Apache POI的便捷包装。

import org.apache.poi.hssf.usermodel.HSSFWorkbook
import com.emmanuelrosa.frostedsheets.* 

/*
 * Creates a workbook with Apache POI and decorates it
 * with Frosted Sheets.
 */
def workbook = new FrostedWorkbook(new HSSFWorkbook())

workbook['Students'] << [
    ['First Name', 'Last Name', 'Age'],
    ['John', 'Doe', '20'],
    ['Jane', 'Smith', '18']
]

workbook['Courses'] << [
    ['Course Name', 'Number of Units'],
    ['Algebra', 3],
    ['English Grammar', 5]
]

/*
 * workbook is an instance of FrostedWorkbook, 
 * which implements the Workbook interface.
 * The writeProtectWorkbook() method is provided
 * by HSSFWorkbook (it's not in the interface).
 * FrostedWorkbook.workbook is the decorated HSSFWorkbook
 */
workbook.workbook.writeProtectWorkbook('password', 'user')
workbook.write(response.outputStream)

Excel工作簿加密
FrostedSheets现在为XLSX工作簿提供加密。您只需要使用0.3.0或更高版本:

import com.emmanuelrosa.frostedsheets.* 

/*
 * Creates an XLSX workbook with Apache POI and decorates it
 * with Frosted Sheets.
 */
def workbook = FrostedWorkbook.createXLSX()

workbook['Students'] << [
    ['First Name', 'Last Name', 'Age'],
    ['John', 'Doe', '20'],
    ['Jane', 'Smith', '18'],
]

workbook['Courses'] << [
    ['Course Name', 'Number of Units'],
    ['Algebra', 3],
    ['English Grammar', 5]
]
    
workbook.writeEncrypted(outputStream: response.outputStream, password: 'password')

警告:在加密过程中，未加密地将工作簿写出到临时存储中。默认值为字节数组(RAM)，但也可以使用临时文件。
另外，请确保将响应头中的文件扩展名更改为xlsx。