Grails - 从 if 和 else 中使用 null 属性创建条件

Question

我正在使用 Grails 2.3.4。我正在尝试检索具有特定条件的域对象，但是当属性为空时我很难绕过。这是一个例子。

class Domain1 {
   int locationId
   Domain2 domain2
   Domain3 domain3
   ...
   static constraints = {
      locationId(nullable:false, blank:false, unique:false)
      domain2(nullable:true)
      domain3(nullable:true)
      ...
   }
}

class Domain2 {
   int locationId
   ...
   static constraints = {
      locationId(nullable:false, blank:false, unique:false)
      ...
   }
}

class Domain3 {
   int locationId
   ...
   static constraints = {
      locationId(nullable:false, blank:false, unique:false)
      ...
   }
}

如果locationId在Domain1中有效，并且locationId在Domain2中有效(如果不为null)，并且locationId在Domain3中有效(如果不为null)，则查询仅假设返回单个Domain1。

def getDomain1ById(Long sid) {
   return Domain1.createCriteria().get {
      idEq(sid)
      'in' ("locationId", Util.getUserAccessLocationList())
      // What I want to do is if(domain2 != null) check location
      or {
         isNull("domain2")
         domain2 {
            'in' ("locationId", Util.getUserAccessLocationList())
         }
      }
      // What I want to do is if(domain3 != null) check location
      or {
         isNull("domain3")
         domain3 {
            'in' ("locationId", Util.getUserAccessLocationList())
        }
      }
   }
}

我错过了什么。如果domain2和domain3不为空，则查询工作正常

Answer 1

默认情况下，Grails 条件查询使用内部联接。要实现您想要的条件行为，请更改为左连接:

Domain1.createCriteria().get {
    createAlias('domain2', 'd2', CriteriaSpecification.LEFT_JOIN)
    createAlias('domain3', 'd3', CriteriaSpecification.LEFT_JOIN)
    idEq(sid)
    'in' ("locationId", locIds)
    or {
        isNull("domain2")
        'in' ("d2.locationId", locIds)
    }
    or {
       isNull("domain3")
       'in' ("d3.locationId", locIds)
    }
}