perl - Perl错误使用未初始化的值$ _代替(s///)

Question

问候语我尝试按照本教程将文件读入哈希哈希。

http://docstore.mik.ua/orelly/perl/prog3/ch09_04.htm

我的文字输入文件是

event_a1_x1: email1=xxx@gmail.com email2=yyy@gmail.com email1_cnt=3 
event_a1_x2: email1=xxx@gmail.com email2=yyy@gmail.com email1_cnt=3 
event_b2_y1: email1=xxx@gmail.com email2=yyy@gmail.com email1_cnt=3 
event_b2_y2: email1=xxx@gmail.com email2=yyy@gmail.com email1_cnt=3 
event_c3_z1: email1=xxx@gmail.com email2=yyy@gmail.com email1_cnt=3 
event_c3_z2: email1=xxx@gmail.com email2=yyy@gmail.com email1_cnt=3

我的代码是

#!/usr/bin/perl
use strict;
use warnings;

my $file = $ARGV[0] or die "Need to get config file on the command line\n";

open(my $data, '<', $file) or die "Could not open '$file' $!\n";

my %HoH;
#open FILE, "filename.txt" or die $!;
my $key;
my $value;
my $who;
my $rec;
my $field;

while ( my $line = <$data>) {
    print $line;
    next unless (s/^(.*?):\s*//);
    $who = $1;
    #print $who;
    $rec = {};
    $HoH{$who} = $rec;
    for $field ( split ) {
        ($key, $value) = split /=/, $field;
        $rec->{$key} = $value;
    }
}

我不断收到此错误...

Use of uninitialized value $_ in substitution (s///) at ./read_config.pl line 18, <$data> line 1. 

Answer 1

这与设置和使用$_(默认输入和模式搜索空间)有关。

在while (<$fh>)中，将从文件句柄读取的内容分配给$_。然后您的正则表达式s///和print和split可以使用它。参见General Variables in perlvar。

但是，一旦我们专门分配了一个变量while (my $line = <$fh>)，此交易就关闭了，并且没有设置$_。因此，当您以后以依赖于$_的方式使用正则表达式替换时，会找到uninitialized变量。

一致地使用默认的$_，或者(一致地)不使用。所以，要么

while (<$fh>) { 
    print;
    # same as posted
}

要么

while (my $line = <$fh>) {
    # ...
    next unless $line =~ s/^(.*?):\s*//;
    # ...
    foreach my $field (split ' ', $line) {
        # ...
    }
}

代码中还有很多可以改进的地方，但这将带我们到其他地方。