我正在寻找一种将 Put() 函数与我创建的自定义类型一起使用的方法。我该怎么做?
with Ada.Text_IO, Ada.Integer_Text_IO;
use Ada.Text_IO, Ada.Integer_Text_IO;
procedure main is
type count is range -2..2 ;
begin
Put(counter);
end main;
这是我得到的:
Builder results
C:\Users\***********\Desktop\ada project\src\main.adb
26:11 expected type "Standard.Integer"
26:7 no candidate interpretations match the actuals:
26:7 possible missing instantiation of Text_IO.Integer_IO
最佳答案
您缺少实例 Counter
,并且没有采用 Count
类型参数的子程序 Put
。一些选项:
- 选项 1 - 使用
Image
属性。
with Ada.Text_IO;
procedure Main is
type Count is range -2 .. 2;
Counter : Count := 1;
begin
Ada.Text_IO.Put (Counter'Image); -- Counter'Image returns a String
-- or
Ada.Text_IO.Put (Count'Image (Counter));
end Main;
- 选项 2 - 转换为类型
Integer
。
with Ada.Integer_Text_IO;
procedure Main is
type Count is range -2 .. 2;
Counter : Count := 1;
begin
Ada.Integer_Text_IO.Put (Integer (Counter));
end Main;
- 选项 3 - 定义子类型而不是类型。
with Ada.Integer_Text_IO;
procedure Main is
subtype Count is Integer range -2 .. 2;
Counter : Count := 1;
begin
Ada.Integer_Text_IO.Put (Counter);
end Main;
- 选项 4 - 实例化通用包
Ada.Text_IO.Integer_IO
。
with Ada.Text_IO;
procedure Main is
type Count is range -2 .. 2;
Counter : Count := 1;
package Count_Text_IO is
new Ada.Text_IO.Integer_IO (Count);
begin
Count_Text_IO.Put (Counter);
end Main;
关于阿达 : put() with custom type,我们在Stack Overflow上找到一个类似的问题: https://stackoverflow.com/questions/58249229/