f# - 是否有一个通用函数可以识别嵌套可区分联合的情况？

Question

我创建了一个嵌套的可区分联合 (DU)，如下所示:

type OptimizationPeriod = | All
                          | Long
                          | Short

type OptimizationCriterion = | SharpeRatio      of OptimizationPeriod
                             | InformationRatio of OptimizationPeriod
                             | CalmarRatio      of OptimizationPeriod

还有一个非嵌套的 DU:

type Parallelism = Sequential | PSeq

我有一个 JSON 配置文件，其中包含定义 DU 案例的字符串。以下函数设法识别非嵌套 Parallelism DU 的情况:

let stringToDUCase<'t> (name: string) : 't =
        let dUCase =
            Reflection.FSharpType.GetUnionCases( typeof<'t> )
            |> Seq.tryFind (fun uc -> uc.Name = name)
            |> Option.map (fun uc -> Reflection.FSharpValue.MakeUnion( uc, [||] ) :?> 't)
        match dUCase with
        | Some x -> x
        | _ -> let msg = sprintf "config.json - %s is not a case in DU %A" name typeof<'t>
               failwith msg

注意:我当然是从某处复制的，因为这个函数有点让我头疼，向作者道歉，因为我不记得它是从哪里来的。

不幸的是，这个函数无法识别嵌套 DU 的大小写:

stringToDUCase<OptimizationCriterion> config.Trading.Criterion
System.Exception: config.json - SharpeRatio All is not a case in DU FractalTypes.OptimizationCriterion

两个问题:

1) 我能够编写一个函数来处理特定 OptimizationCriterion DU 并且能够识别情况。是否有符合 stringToDUCase 的generic 函数可以做同样的事情？

2) 使用 OptimizationCriterion*OptimizationPeriod 类型的元组而不是嵌套 DU 会更好吗？ (我可能不得不调用 stringToDUCase 两次，但这不是问题)

Answer 1

像 All 这样的“空”DU 案例只是一个值，但是像 SharpeRatio 这样的“非空”DU 案例实际上是一个函数，它有一个值并且返回类型。在这种情况下，SharpeRatio 的类型为 OptimizationPeriod -> OptimizationCriterion。

您现有的 stringToDUCase 函数总是将一个空数组传递给 MakeUnion(暗示一个空的 DU 案例)。因此，这是适用于任何 DU 案例的函数的修改版本:

let stringToParamDUCase<'t> (name: string) =
    Reflection.FSharpType.GetUnionCases(typeof<'t>)
    |> Seq.tryFind (fun uc -> uc.Name = name)
    |> Option.map (fun uc ->
        fun (parameters:obj []) -> Reflection.FSharpValue.MakeUnion(uc, parameters) :?> 't)
    |> Option.defaultWith (fun () ->
        failwith (sprintf "config.json - %s is not a case in DU %A" name typeof<'t>))

注意它返回一个函数obj[] -> 't。我还稍微简化了错误处理。

你可能会这样使用它:

let myOptimizationPeriod = stringToParamDUCase<OptimizationPeriod> "All" [||]
let f = stringToParamDUCase<OptimizationCriterion> "SharpeRatio"
let myOptimizationCriterion = f [|All|]