xslt-2.0 - 为什么 index-of() 在应用于一系列唯一节点时会返回多个值？

Question

我正在使用 xpath2 的索引值来返回排序的节点序列中的 current() 索引。使用 SAXON，节点的排序序列是唯一的，但 index-of 返回两个值的序列。

这不会一直发生，只是偶尔发生，但我找不到任何原因。有人可以解释一下发生了什么吗？

我已经根据例程给出这种奇怪行为的数据示例编写了一个最小示例。

源数据为:

<data>
<student userID="1" userName="user1"/>
<session startedOn="01/16/2012 15:01:18">
</session>
<session startedOn="11/16/2011 13:31:33">
</session>
</data>

我的 xsl 文档将 session 节点放入根模板最顶部的排序序列 $orderd 中:

<xsl:template match="/">
<xsl:variable name="nodes" as="node()*" select="/data/session"></xsl:variable>
<xsl:variable name="orderd" as="node()*">
<xsl:for-each select="$nodes">
<xsl:sort select="xs:dateTime(xs:dateTime(concat(substring(normalize-space(@startedOn),7,4),'-',substring(normalize-space(@startedOn),1,2),'-',substring(normalize-space(@startedOn),4,2),'T',substring(normalize-space(@startedOn),12,8)))
)" order="ascending"/>
    <xsl:sequence select="."/>
</xsl:for-each>
</xsl:variable>

由于节点已经由@startOn 排序，但顺序相反，序列 $orderd 应该与文档排序序列 $nodes 相同，但顺序相反。

当我使用 for-each 语句创建输出时，我发现在使用 index-of 测试时，这两个节点以某种方式被视为相同。

下面的代码用于输出数据(并且紧跟在上面的块之后):

<output>
<xsl:for-each select="$nodes">
<xsl:sort select="position()" order="descending"></xsl:sort>
<xsl:variable name="index" select="index-of($orderd,current())" as="xs:integer*"></xsl:variable>
<xsl:variable name="pos" select="position()"></xsl:variable>        
<session reverse-documentOrder="{$pos}"  sortedOrder="{$index}"/>
</xsl:for-each>
</output>

正如输出(如下所示)所示，index-of 函数返回序列 (1,2)，这意味着它认为两个节点相同。我检查了用于对值进行排序的表达式，它生成了不同且格式正确的日期时间字符串。

<output>
<session reverse=documentOrder="1"
        sortedOrder="1 2"/>
<session reverse-documentOrder="2"
        sortedOrder="1 2"/>
</output>

Answer 1

不靠generate-id()函数，是XSLT函数，不是XPath函数，可以写一个简单的index-of()对节点身份进行操作的函数 :

<xsl:stylesheet version="2.0"
    xmlns:xsl="http://www.w3.org/1999/XSL/Transform"
    xmlns:xs="http://www.w3.org/2001/XMLSchema"
    xmlns:my="my:my">
    <xsl:output omit-xml-declaration="yes" indent="yes"/>
    
    <xsl:variable name="vNum3" select="/*/*[3]"/>
    
    <xsl:variable name="vSeq" select="/*/*[1], /*/*[3], /*/*[3]"/>
    
 <xsl:template match="/">
   <xsl:sequence select="my:index-of($vSeq, $vNum3)"/>
 </xsl:template>
 
 <xsl:function name="my:index-of" as="xs:integer*">
  <xsl:param name="pSeq" as="node()*"/>
  <xsl:param name="pNode" as="node()"/>
  
  <xsl:for-each select="$pSeq">
    <xsl:if test=". is $pNode">
      <xsl:sequence select="position()"/>
    </xsl:if>
  </xsl:for-each>
 </xsl:function>
</xsl:stylesheet>

当此转换应用于以下 XML 文档时 :

<nums>
  <num>01</num>
  <num>02</num>
  <num>03</num>
  <num>04</num>
  <num>05</num>
  <num>06</num>
  <num>07</num>
  <num>08</num>
  <num>09</num>
  <num>10</num>
</nums>

返回想要的正确结果 :

2 3

说明 :使用is运算符(operator)。