haskell - 使用量化约束导出 Ord (forall a. Ord a => Ord (f a))

Question

通过量化约束，我可以推导出 Eq (A f)正好？但是，当我尝试导出 Ord (A f) 时，它失败了。当约束类具有父类(super class)时，我不明白如何使用量化约束。我如何得出 Ord (A f)和其他具有父类(super class)的类？

> newtype A f = A (f Int)
> deriving instance (forall a. Eq a => Eq (f a)) => Eq (A f)
> deriving instance (forall a. Ord a => Ord (f a)) => Ord (A f)
<interactive>:3:1: error:
    • Could not deduce (Ord a)
        arising from the superclasses of an instance declaration
      from the context: forall a. Ord a => Ord (f a)
        bound by the instance declaration at <interactive>:3:1-61
      or from: Eq a bound by a quantified context at <interactive>:1:1
      Possible fix: add (Ord a) to the context of a quantified context
    • In the instance declaration for 'Ord (A f)'

PS。我还检查了ghc proposals 0109-quantified-constraints .使用 ghc 8.6.5

Answer 1

问题是 Eq是 Ord 的父类(super class), 和约束 (forall a. Ord a => Ord (f a))不包含父类(super class)约束 Eq (A f)这是声明 Ord (A f) 所必需的实例。

我们有(forall a. Ord a => Ord (f a))

我们需要Eq (A f) ，即 (forall a. Eq a => Eq (f a)) ，我们所拥有的并不暗示这一点。

解决方法:添加(forall a. Eq a => Eq (f a))到Ord实例。

(我实际上不明白 GHC 给出的错误信息与问题有何关系。)

{-# LANGUAGE QuantifiedConstraints, StandaloneDeriving, UndecidableInstances, FlexibleContexts #-}

newtype A f = A (f Int)
deriving instance (forall a. Eq a => Eq (f a)) => Eq (A f)
deriving instance (forall a. Eq a => Eq (f a), forall a. Ord a => Ord (f a)) => Ord (A f)

或者更整洁一点:

{-# LANGUAGE ConstraintKinds, RankNTypes, KindSignatures, QuantifiedConstraints, StandaloneDeriving, UndecidableInstances, FlexibleContexts #-}

import Data.Kind (Constraint)

type Eq1 f = (forall a. Eq a => Eq (f a) :: Constraint)
type Ord1 f = (forall a. Ord a => Ord (f a) :: Constraint)  -- I also wanted to put Eq1 in here but was getting some impredicativity errors...

-----

newtype A f = A (f Int)
deriving instance Eq1 f => Eq (A f)
deriving instance (Eq1 f, Ord1 f) => Ord (A f)