arrays - 2个哈希数组之间的算术运算

Question

我有一个带有 YAML 的哈希数组，它取自 linux 命令。我有另一个哈希数组，具有相同的 YAML 集，但具有不同的值，由稍后运行的相同命令执行。

例如。

content.none: 
  bytes:  31046
content.image.gif: 
  bytes:  0

和

content.none: 
  bytes:  31050
content.image.gif: 
  bytes:  0

现在，我正在寻找值之间的数学运算。我正在寻找输出

content.none: 
  bytes:  4
content.image.gif: 
  bytes:  0

这是哈希中相应值之间的数学运算结果。

我试过迭代和做 diff，但它看起来像一个累积输出。

%host_stat_new=New stats
 %host_stat_old=Old stats (taken from stats.yml, which contains old data)
while (true){
open my $FH1, ">stats.yml" or die "cannot write to stat file because $!\n";
foreach my $line4 (keys %host_stat_new){
        print $FH1 "$line4:\n";
        foreach my $line5 (keys %{$host_stat_new{$line4}}) {
                print $FH1 "  $line5: \n";
                foreach my $line6 (keys %{$host_stat_new{$line4}{$line5}}){
                my $diff1 = $host_stat_new{$line4}{$line5}{$line6};
                my $diff2 = $host_stat_old{$line4}{$line5}{$line6};


$math=$diff1-$diff2;
#$host_stat1{$line4}{$line5}{$line6} = $math;
$host_stat_new{$line4}{$line5}{$line6} = $math;
                    print $FH1 "    $line6:  $host_stat_new{$line4}{$line5}{$line6}\n";
                    }
            }


    }
}

我在这里做错了什么？有没有什么模块可以做到这一点？

Answer 1

只需使用一些好的 ole 递归来获得差异。此函数假定数据结构相同，可以添加功能以确认:

use YAML;

use strict;
use warnings;

my $str1 = <<YAML_STRING1;
content.none: 
  bytes:  31046
content.image.gif: 
  bytes:  0
YAML_STRING1

my $str2 = <<YAML_STRING2;
content.none: 
  bytes:  31050
content.image.gif: 
  bytes:  0
YAML_STRING2

my $data1 = Load($str1);
my $data2 = Load($str2);

my $diff = diff_recurse($data2, $data1);

print Dump($diff);

sub diff_recurse {
    my ($str1, $str2) = @_;

    my $diff;

    if ('HASH' eq ref $str1) {
        $diff = {};
        for my $key (keys %$str1) {
            $diff->{$key} = diff_recurse($str1->{$key}, $str2->{$key});
        }

    } elsif ('ARRAY' eq ref $str1) {
        $diff = [];
        for my $i (0..$#$str1) {
            $diff->[$i] = diff_recurse($str1->[$i], $str2->[$i]);
        }

    } elsif (my $unknown = ref $str1) {
        die "Unknown type $unknown\n";

    } elsif ($str1 =~ /^[\d\.]+$/) {
        $diff = $str1 - $str2;
    } else {
        $diff = $str1;
    }

    return $diff;
}

输出

---
content.image.gif:
  bytes: 0
content.none:
  bytes: 4