haskell - 单子(monad)-tf : MonadReader instance for MonadState

Question

考虑下一个例子。我有一个 monad MyM，它只是一个 StateT

{-# LANGUAGE TypeFamilies #-}

import Control.Monad.State
import Control.Monad.Reader

type MyS = Int
type MyM = StateT MyS

通常MyM用于读写MyS状态，所以我有如下函数:

f1 :: (MonadState m, StateType m ~ MyS) => m ()
f1 = modify (+1)

但有时我只需要读取 MyS，所以我想要 MonadReader 上下文而不是 MonadState:

f2 :: (MonadReader m, EnvType m ~ MyS) => m Int
f2 = liftM (+1) ask

我想写这样的东西:

f3 :: (MonadState m, StateType m ~ MyS) => m Int
f3 = f1 >> f2

所以基本上我需要每个 MonadState 实例也是具有相应系列类型的 MonadReader 实例。有点像

instance MonadState m => MonadReader where
  type EnvType m = StateType m
  ...

但我找不到如何进行类型检查的方法。是否可以表达MonadState和MonadReader之间的这种关系？

谢谢。

Answer 1

听起来您想要的本质上是 ask与 get 具有相同的效果.我不禁想知道你为什么不直接使用 get在那种情况下:)

如果您的目标是根据可用的内容编写读取状态或环境的代码，您必须询问您打算做什么，比如 ReaderT r (StateT s m) a ，你有两个。因此，您不能只做:

instance MonadState m => MonadReader m where
  type EnvType m = StateType m
  ask = get

因为您会与现有实例发生冲突。但是，您可以:

{-# LANGUAGE GeneralizedNewtypeDeriving, TypeFamilies #-}
newtype ReadState m a = RS { unRS :: m a }
  deriving (Monad)

instance MonadState m => MonadReader (ReadState m) where
  type EnvType (ReadState m) = StateType m
  ask = RS get
  local f (RS m) = RS $ do
    s <- get
    modify f
    x <- m
    put s
    return x

然后如果你有一个像f2这样的多态读取器值, 你可以拉一个 MonadState用unRS出来.如果你想使用一些更狡猾的扩展，试试 RankNTypes :

useStateAsEnv :: (MonadState n) => (forall m . (MonadReader m, EnvType m ~ StateType n) => m a) -> n a
useStateAsEnv m = unRS m

然后你可以做 useStateAsEnv (liftM (+1) ask)得到 MonadState值(value)。然而，我还没有彻底研究这在实践中有多大用处——生成 forall m. MonadReader m => m a 类型的值。 ，你几乎只能使用 ask , local , 和 monadic 函数。

这是一个类似的，不太通用但可能更有用的东西，使用标准转换器:

readerToState :: (Monad m) => ReaderT r m a -> StateT r m a
readerToState reader = StateT $ \env -> do
  res <- runReaderT reader env
  return (res, env)

---

编辑:稍后再考虑这个问题，您可能可以将其推广到具有 lift . runReaderT reader =<< get 的任何状态 monad 转换器。 , 但类型开始变得相当笨拙:

:: (Monad m, MonadTrans t, MonadState (t m)) => ReaderT (StateType (t m)) m b -> t m b

是以上内容的概括，但实际上可能没有用。