class - Common Lisp 类型与类的区别

Question

在 Common Lisp class hierarchy 的帖子中, Rainer Joswig 和 Joshua Taylor 仔细区分了内置 Common Lisp types 和 classes 之间的一些差异，其中类构成了 CLOS 对基线的扩展的一部分。类型/类(加上 mop)的区别也反射(reflect)在 Pfeil 的综合 hierarchy diagram 中。 .使用该图，似乎可以提取两个不同的层次结构。特别是，我目前对层次结构的顶部最感兴趣；即 t 的直接子类型和子类(因为 t 既是类型又是类)。以下是从图中提取的一些临时子类型/子类:

对于类型层次，t的直接子类型似乎是atom、character、random-state, hash-table, restart, readtable, package, 路径名, 流、函数、数组、序列、数字和条件。所有其他类型，如 float 或 list 都是这些类型之一的子类型。类型层次结构也不是严格的层次结构(因为 (subtype t t) => T，但这似乎是唯一的异常(exception))。 (ps:symbol和structure-object类型没有包含在图中，但也可能是t的直接子类型。)

对于类层次结构，t 的直接子类包括上述所有类型的对应类(atom 除外，可能还有structure-object 现在是 standard-object(?)) 的子类，加上 standard-object。

MOP 通过添加 metaobject 类(加上一些元子类)扩展了 CLOS，但似乎没有添加到 t 的直接子类中。

有人可以验证这种理解是否正确，或者提供额外的说明吗？

注意:我在上面的类型层次描述中发现了至少一个错误。所有列出的子类型(character 等)显然都是 atom 的子类型，因此它们不是 t 的直接子类型。 t 的唯一其他直接子类型似乎是 sequence，因为序列可以是 cons(非原子)。此外，symbol实际上包含在图中，也是atom的子类型。

Answer 1

在 LispWorks 中绘制 T 的 CL 子类型:

寻找子类型:

(defun find-synonym-types (type1 types)
  (remove-if-not (lambda (type2)
                   (and (not (eq type1 type2))
                        (subtypep type1 type2)
                        (subtypep type2 type1)))
                 types))

(defun find-all-types-in-packages (packages &key include-nil)
  (let ((types nil))
    (loop for package in packages
          when (find-package package)
          do (do-external-symbols (sym (find-package package))
               (when (ignore-errors (subtypep sym t))
                 (let ((synonyms (find-synonym-types sym types)))
                   (if synonyms
                       (pushnew sym (get (first synonyms) :type-synonyms))
                     (pushnew sym types))))))
    (if include-nil types (remove nil types))))

(defun direct-subtypes (supertype &key all-types)
  (loop with subtypes = (remove supertype (loop for type in all-types
                                                when (subtypep type supertype)
                                                collect type))

        for type in subtypes
        when (loop for type2 in (remove type subtypes)
                   never (subtypep type type2))
        collect type))

绘图:

#+capi
(defun class-color (class-name)
  (typecase (find-class class-name)
    (standard-class  :blue)
    (built-in-class  :violet)
    (structure-class :brown)
    (otherwise       :red)))

#+capi
(defun graph-subtypes-from-t ()
  (let ((all-types (find-all-types-in-packages '("CL" "CLOS"))))
    (capi:contain
     (make-instance
      'capi:graph-pane
      :roots '(t)
      :children-function (lambda (type)
                           (direct-subtypes type :all-types all-types))
      :node-pane-function #'(lambda (graph-pane node)
                              (declare (ignore graph-pane))
                              (make-instance
                               'capi:item-pinboard-object
                               :text (format
                                      nil "~{~a~^, ~}"
                                      (cons node
                                            (get node :type-synonyms)))
                               :graphics-args `(:foreground
                                                ,(if (find-class node
                                                                 nil)
                                                     (class-color node)
                                                   :black))))
      :edge-pane-function #'(lambda (self from to)
                              (declare (ignore self from to))
                              (make-instance
                               'capi:arrow-pinboard-object
                               :graphics-args '(:foreground
                                                :grey))))
     :title "Common Lisp Subtypes in LispWorks")))

图表

具有相应 CLOS 类的类型用蓝色书写，结构类用棕色书写。 NIL 类型未绘制。包括来自 CLOS MOP 的类型/类。有些类型有多个名称。另请注意，此图特定于 LispWorks，尤其是哪些类型实际上也是结构、CLOS 类、内置类或其他东西。