ios - 如何将 "C++ completion handler"传递给 NSURLSessionDataTask 来处理它返回的数据？

Question

我们的应用程序主要是用C++编写的，其核心是多个平台(Win、Mac、Android、iOS)共享的静态库。

我们正在添加 iOS 支持，并拥有一系列使用 libcurl 的函数来执行与我们的服务器的所有 HTTP get/post 通信。

但对于 iOS，我们现在使用 NSURLSession 实现这些调用。

我的问题非常简单，为 NSURLSessionDataTask 提供 C++completionHandler 的代码是什么样的？

也许我的思考方式是错误的，但这是我能想到的最清楚的提问方式。

使用世界上的示例代码，我尝试了以下操作，但无济于事。完成处理程序中的 Objective-C++ 代码永远不会被调用。它返回到 C++ 代码并且永远不会返回。

这是 Objective-C++ 函数:

std::string get(std::string urlStr)
{
    NSURLSession *defaultSession = [NSURLSession sharedSession];

    NSURL * url = [NSURL URLWithString:[NSString stringWithUTF8String:urlStr.c_str()]];

    __block std::string returnVal;

    NSURLSessionDataTask * dataTask = [defaultSession dataTaskWithURL:url
                                                         completionHandler:^(NSData *data, NSURLResponse *response, NSError *error) {
        if(error == nil)
        {
            NSString * text = [[NSString alloc] initWithData: data encoding: NSUTF8StringEncoding];
            NSLog(@"Data = %@",text);

            returnVal = std::string([text UTF8String]);
        }

    }];

    [dataTask resume];

    return returnVal;
}

这就是我在 C++ 中调用该代码的方式:

    response = get(url);
    fprintf(stderr, "Data in C++: %s", response.c_str());

Answer 1

如果我理解你的问题，你希望 get(std::string) 在完成获取后“给你回电话”。如果您愿意更改 get 的接口(interface)，那么一种方法是将 std::function 作为参数传递...

void get(std::string urlStr, std::function<void(std::string)> callback)
{
  ...
  NSURLSessionDataTask* dataTask = 
    [defaultSession 
      dataTaskWithURL:url 
      completionHandler:
        ^(NSData *data, NSURLResponse *response, NSError *error) {
          if(error == nil)
          {
             NSString * text = [[NSString alloc] initWithData: data encoding: NSUTF8StringEncoding];
             NSLog(@"Data = %@",text);

             // invoke the callback here...
             callback(std::string([text UTF8String]));
          }
        }];
  ...
}

这将像这样使用......

void callbackFunc(std::string data)
{
  ...
}

get("...", callbackFunc);

构建此结构的另一种方法是使用 C++ 的新 std::promise 和 std::future 类型...

std::future<std::string> get(std::string urlStr)
{
  ...
  __block std::promise<std::string> p{};

  NSURLSessionDataTask* dataTask = 
    [defaultSession 
      dataTaskWithURL:url 
      completionHandler:
        ^(NSData *data, NSURLResponse *response, NSError *error) {
          if(error == nil)
          {
             NSString * text = [[NSString alloc] initWithData: data encoding: NSUTF8StringEncoding];
             NSLog(@"Data = %@",text);

             // Set the result value here...
             p.set_value(std::string([text UTF8String]));
          }
        }
    ];
  ...
  return p.get_future();
}

然后可以像这样使用......

auto result = get("...");

// other processing here ...
...

auto result_value = result.get();

注意:我应该指出，我假设使用 c++11/14。如果您使用的是 c++03，那么您仍然可以通过使用 boost::function 或裸函数指针来使用第一种方法 - void(*)(std::string)。我也不太熟悉 OS X 的 block 功能，所以要小心我的语法。