我是贝叶斯分析的新手,正在尝试使用 rstan 来估计后验密度分布。该练习试图使用 stan 重新创建我的大学给我们的示例,但我对如何正确转换变量有点困惑。我当前的代码运行没有错误,但结果与大学给我们的结果不符(尽管很接近),为清楚起见,下图使用黑色的 stan 估计。我通过查阅手册并将随机位拼凑在一起来使代码工作,但特别是我不太确定为什么需要 target
以及 gamma 转换是否确实正确。任何指导将不胜感激!
模型
标准规范
data {
int<lower=0> I;
int<lower=0> n[I];
int<lower=0> x[I];
real<lower=0> a;
real<lower=0> b;
real m;
real<lower=0> p;
}
parameters {
real<lower=0> lambda;
real mu;
real<lower=0, upper=1> theta[I];
}
transformed parameters {
real gam[I];
for( j in 1:I)
gam[j] = log(theta[j] / (1-theta[j])) ;
}
model {
target += gamma_lpdf( lambda | a, b);
target += normal_lpdf( mu | m , 1/sqrt(p));
target += normal_lpdf( gam | mu, 1/sqrt(lambda));
target += binomial_lpmf( x | n , theta);
}
R代码
library(rstan)
fit <- stan(
file = "hospital.stan" ,
data = dat ,
iter = 20000,
warmup = 2000,
chains = 1
)
数据
structure(
list(
I = 12L,
n = c(47, 211, 810, 148, 196, 360, 119, 207, 97, 256, 148, 215),
x = c(0, 8, 46, 9, 13, 24, 8, 14, 8, 29, 18, 31),
a = 2,
b = 2,
m = 0,
p = 0.01),
.Names = c("I", "n", "x", "a", "b", "m", "p")
)
---更新解决方案---
Ben Goodrich 指出的问题是,我是从 theta 推导 Gamma 的,而 Gamma 应该是相反的,因为 Gamma 是我的随机变量。正确的 stan 代码如下。
data {
int<lower=0> I;
int<lower=0> n[I];
int<lower=0> x[I];
real<lower=0> a;
real<lower=0> b;
real m;
real<lower=0> p;
}
parameters {
real<lower=0> lambda;
real mu;
real gam[I];
}
transformed parameters {
real<lower=0 , upper=1> theta[I];
// theta = inv_logit(gam); // Alternatively can use the in-built inv_logit function which is vectorised
for(j in 1:I){
theta[j] = 1 / ( 1 + exp(-gam[j]));
}
}
model {
target += gamma_lpdf( lambda | a, b);
target += normal_lpdf( mu | m , 1/sqrt(p));
target += normal_lpdf( gam | mu, 1/sqrt(lambda));
target += binomial_lpmf( x | n , theta );
}
最佳答案
作为提示,尝试将 gam
(ma) 放在 parameters
block 中,然后在 transformed 中声明和定义
根据您一开始给出的分布进行分组。theta
parameters
Stan 的初学者通常认为 Stan 有能力从逻辑上计算出你的 Stan 程序的含义,但实际上它被相当字面地转译为 C++ 和来自转换参数
的代码行和 model
block 被一遍又一遍地执行。
gam
(ma) 或 theta
是原始参数会产生差异的原因与变量变化原则有关。如果您真的想要,如果您向 target
添加雅可比行列式项(以对数为单位),您可以获得与原始参数化相同的结果,但是通过移动 可以更容易地避免这种情况gam
(ma) 到 parameters
block ,theta
到 transformed parameters
block 。有关变量更改原则的详细信息,请参阅此 case study .
关于r - 在 rstan 中转换变量(贝叶斯分析),我们在Stack Overflow上找到一个类似的问题: https://stackoverflow.com/questions/41839180/