我正在编写一个 XQuery,它需要检查正在运行的 XQuery 版本(eXist、Saxon 等)。是否有一个标准函数可以返回 XQuery 的系统属性,例如版本、供应商等?
我知道有一些系统特定的调用,比如 eXist 的
system:get-version()
但我正试图找到一个可以在所有平台上运行的标准函数。
例如在XSLT中我们有:
Version:
<xsl:value-of select="system-property('xsl:version')" />
<br />
Vendor:
<xsl:value-of select="system-property('xsl:vendor')" />
<br />
Vendor URL:
<xsl:value-of select="system-property('xsl:vendor-url')" />
它们对XQuery的功能是否相似?
最佳答案
您可以使用 XQuery 3.0 函数 function-lookup
检查特定于实现的函数是否存在,以检查处理器。所有支持 XQuery 3.0 的处理器都应该能够处理这个。
declare function local:exist() as xs:boolean {
try {
if (not(empty(function-lookup(xs:QName('system:get-version'), 0))))
then true()
else false()
} catch * {
false()
}
};
(: works only on Saxon PE and EE, fails in HE since HE does not support XQuery 3.0. It would be nice if saxon had a version function. :)
declare function local:saxon() as xs:boolean {
try {
if (not(empty(function-lookup(xs:QName('saxon:parse'), 1))))
then true()
else false()
} catch * {
false()
}
};
declare function local:marklogic() as xs:boolean {
try {
if (not(empty(function-lookup(xs:QName('xdmp:xquery-version'), 0))))
then true()
else false()
} catch * {
false()
}
};
declare function local:basex() as xs:boolean {
try {
if (not(empty(function-lookup(xs:QName('prof:time'), 1))))
then true()
else false()
} catch * {
false()
}
};
declare function local:get-processor() as xs:string {
if (local:exist()) then "eXist"
else if (local:saxon()) then "Saxon"
else if (local:marklogic()) then "MarkLogic"
else if (local:basex()) then "BaseX"
else "Unknown"
};
local:get-processor()
不幸的是,我无法使用高阶函数使它更优雅,因为特定于实现的函数是在实际调用函数之前执行的。但我相信这也可以写得更优雅。
关于xquery - 我如何编写一个 XQuery 来测试正在使用的 XQuery 版本?,我们在Stack Overflow上找到一个类似的问题: https://stackoverflow.com/questions/20849295/