clojure - 在宏上调用宏

Question

我正在尝试编写一个 Clojure 宏，它创建一个前缀符号列表以从一个简单的中缀符号列表进行评估，比如说 (2 * 3 + 4 * 2) 到一个评估的 (+ (* 2 3) (*4 2))(导致返回 14)。

我写了下面的代码:

(defmacro infix [op inlist]
  (let [[i1 i2 & i3] inlist
        last-group? (nil? (second i3))]  

    (if last-group?
      `(if (= ~op ~i2)
        (~i2 ~i1 ~(first i3)) ; return unevaluated prefix list
        (~i1 ~i2 ~(first i3))) ; return unevaluated infix list
      `(if (= ~op ~i2)
         ; recur with prefix list in i1 position
         (infix ~op ~(conj (rest i3) (list i2 i1 (first i3)) ))
         ; return as list: i1 and i2, recur i3 (probably wrong)
         (~i1 ~i2 (infix ~op ~i3))
         ))))

为了通过使用不同的op(运算符函数)参数递归调用宏来强制执行运算符优先级:

(infix + (infix * (2 * 3 + 4 * 2)))

上面，我只是将它与两个 * 和 + 一起使用，但最终我想为所有人调用宏(或至少为了这个缘故) this exercise ,/* + -) 运算符。

当我执行上面的嵌套宏调用时，出现以下错误:

CompilerException java.lang.RuntimeException: Can't take value of a macro: #'cbat.ch7.ex2/infix, compiling:(/tmp/form-init4661580047453041691.clj:1:1)

为单个运算符和相同运算符的列表调用宏(即 (infix * (2 * 3 * 4)))按预期工作。如果我用单个 (i1 i2 i3) 列表调用宏，如果 op 不同于 i2，它会尝试(可以理解)返回未计算的中缀列表有错误:

ClassCastException java.lang.Long cannot be cast to clojure.lang.IFn  cbat.ch7.ex2/eval3003 (form-init4661580047453041691.clj:1)

我希望递归调用宏意味着我可以在评估整行之前处理未评估的中缀列表，但这似乎不起作用。

---

我很确定后者的 else 分支，内部 if(即 (~i1 ~i2 (infix ~op ~i3)))是不正确的，我可能只需要内部中缀调用，但我更关心在评估之前让不同运算符的嵌套宏调用起作用。

我知道这不是将中缀转换为前缀表示法的常用方法，后来发现了 Dijkstra's shunting-yard algorithm , 但请有人好心地告诉我:

1. 这样的嵌套宏调用是否可能？
2. 我的逻辑是否合理，是否离解决方案不远？如果是这样……
3. ...我需要做出哪些改变才能让一切正常运行？

我非常专注于学习 Clojure，因此非常欢迎任何详尽的解释(如果可能)。

Answer 1

您可以像这段代码演示的那样嵌套宏调用:

(defmacro mac [tag & forms]
  `(do
     (println "mac - enter" ~tag)
     ~@forms
     (println "mac - exit " ~tag)))

(mac :a
  (doseq [i (range 3)]
    (mac :b (println i))))

mac - enter :a
mac - enter :b
0
mac - exit  :b
mac - enter :b
1
mac - exit  :b
mac - enter :b
2
mac - exit  :b
mac - exit  :a

您还可以进行递归宏调用，如下所示:

(defmacro macr [n]
  (if (zero? n)
    1
    `(* ~n (macr ~(dec n)))))

(macr 5)   => 120

在不深入研究您的特定实现的情况下，我建议 2 点:

1. 至少在开始时，让您的表单尽可能简单。这意味着只有 (2 + 3) 这样的形式。尤其不要强制宏在早期版本(或曾经!)中找出运算符优先级。

2. 宏几乎从不是必需的，不幸的是，恕我直言，在学习 Clojure 和其他 lisp 时，宏有点“被夸大了”。我建议您甚至在头一两年内都不要考虑它们，因为它们比函数更脆弱，而且在重要方面也不那么强大(例如，您不能将宏传递给函数)。

更新

每当你想写一些复杂的东西时(宏绝对可以!)，从小处着手 一步一步地建立它。使用the lein-test-refresh plugin和 the Tupelo library绝对有帮助 在这里。

首先，制作尽可能简单的宏并观察其行为:

(ns tst.clj.core
  (:use clj.core clojure.test tupelo.test)
  (:require [tupelo.core :as t] ))
(t/refer-tupelo)

(defn infix-fn [[a op b]]
  (spyx a)
  (spyx op)
  (spyx b)
  )

(defmacro infix [form]
  (infix-fn form))

(infix (2 + 3))

a => 2
op => +
b => 3

对于许多宏，将宏参数发送到辅助函数(如 infix-fn)会很有帮助。这 spyx 通过打印符号及其值来帮助我们。此时，我们可以简单地重新排序 args 转换为前缀表示法，然后我们开始:

(defn infix-fn [[a op b]] (list op a b))

(defmacro infix [form] (infix-fn form))

(deftest master
  (is= 5 (infix (2 + 3)))
  (is= 6 (infix (2 * 3))))

如果我们有一个递归树结构呢？检查我们是否需要在 infix-fn 中递归:

(declare infix-fn)

(defn simplify [arg]
  (if (list? arg)
    (infix-fn arg)
    arg))

(defn infix-fn [[a op b]]
  (list op (simplify a) (simplify b)))

(is= 7 (infix ((2 * 2) + 3)))
(is= 9 (infix ((1 + 2) * 3)))


(is= 35 (infix ((2 + 3) * (3 + 4))))
(is= 26 (infix ((2 * 3) + (4 * 5))))

我不想添加运算符优先级的复杂性。如果绝对必要，我 不会自己编写代码，但会使用 the excellent Instaparse library为此目的。