prolog - 用于从 Prolog 中的复合术语中删除某些术语的谓词

Question

我想写一个 Prolog 谓词，它接受一个复合术语作为它的参数，并输出这个复合术语并删除一些嵌套术语。例如，假设我有一个复合词:

outer_term(level_one(level_two_a(X), level_two_b(Y)), level_one(level_two_b(Z))).

我想写一个谓词 extract_terms/2，它将接受这个词并返回它而不出现 level_two_a/1。

extract_terms(Term, ExtractedTerm) :-
       *** Prolog Magic ***.

在 Prolog 中是否有内置(或半内置)方法来执行此操作？如果没有，我将如何去做呢？我想到的一种方法是使用 =../2 运算符将 Term 转换为列表，然后以某种方式使用一些内置谓词，如 subtract/3摆脱我想要的谓词。我遇到的问题是使用将嵌套术语作为其项目的列表进行这项工作。

如果有任何想法，我将不胜感激，谢谢。

Answer 1

首先，一般准则:

所有可以用模式匹配表达的东西都应该用模式匹配表达。

你问了一个similar question以前，虽然它有点简单。尽管如此，让我们首先考虑更简单的情况:您说动词短语的可能实例是:

VP = vp(vp(verb(making), adj(quick), np2(noun(improvements))))

并且您想提取动词。嗯，最简单的方法是使用模式匹配，或者更一般地说，统一，如下所示:

?- VP = vp(vp(verb(making), adj(quick), np2(noun(improvements)))),
   VP = vp(vp(Verb, _, _)).

这会产生:

Verb = verb(making).

这样，我们就成功地从这样一个短语中“提取”出了verb(making)。

现在，对于您在这个问题中考虑的稍微复杂的任务:此时，您可能想知道您是否选择了数据的良好表示。 (=..)/2 的频繁使用，甚至是非常必要的，通常表明您的表示存在问题，因为这可能意味着您已经失去对数据可能形状的跟踪或控制。

在这个具体案例中，您举例说明:

outer_term(level_one(level_two_a(X), level_two_b(Y)), level_one(level_two_b(Z))).

并且您想删除出现的 level_two_a。您现在当然可以开始处理 (=..)/2，这需要将这些术语转换为列表，然后对这些列表进行一些推理，然后第二次从列表转换回这样的结构。这不是我们想要处理数据的方式。除了其他缺点之外，它还会排除我们期望从关系中获得的更一般的使用模式。

相反，让我们修复数据表示，以便我们可以清楚地区分不同的情况。例如，不是“硬编码”我们需要区分仿函数内部情况的参数，而是让我们显式进行区分:我们希望能够区分，通过模式匹配，从级别 2 到级别 1。

因此，以下表示表明了自己:

outer_term([level(1, [level(2, X),
                      level(2, Y)]),
            level(1, [level(2, Z)])]).

这可能需要一些额外的属性，例如 a 和 b，我将扩展此表示以表示此类属性作为一个简单的练习。不过，总体思路应该很清楚:我们因此实现了一个统一表示，我们可以很容易地象征性地推理它。

现在很容易描述此类级别的(可能嵌套的)列表与没有“级别 2”元素的级别之间的关系:

without_level_2(Ls0, Ls) :-
        phrase(no_level_2(Ls0), Ls).

no_level_2([]) --> [].
no_level_2([L|Ls]) -->
        no_level_2_(L),
        no_level_2(Ls).

no_level_2_(level(2,_))   --> [].
no_level_2_(level(L,Ls0)) --> [level(L,Ls)],
        { dif(L, 2),
          without_level_2(Ls0, Ls) }.

参见 dcg有关此形式主义的更多信息。

示例查询:

?- outer_term(Ts0),
   without_level_2(Ts0, Ts).

产量:

Ts = [level(1, []), level(1, [])] .

请注意，要真正从这种表示中受益，您首先需要通过使用或生成此类形状的术语来获得它。确保这一点后，您可以方便地坚持模式匹配来区分案例。在这种方法的主要优点中，我们发现方便、性能 和通用性。例如，我们不仅可以使用上面显示的 DCG 来提取，还可以生成这种形式的术语:

?- length(Ls0, _), without_level_2(Ls0, Ls).
Ls0 = Ls, Ls = [] ;
Ls0 = [level(2, _56)],
Ls = [] ;
Ls0 = Ls, Ls = [level(_130, [])],
dif(_130, 2) ;
Ls0 = [level(_150, [level(2, _164)])],
Ls = [level(_150, [])],
dif(_150, 2) .

这是一个真正的关系，可以在所有方向上使用。出于这个原因，我在谓词名称中避免诸如“extract”、“remove”等命令式名称，因为它们总是暗示特定的方向使用，而不是做对谓词的普遍性的公正。