sql-server - 如何为每个表创建默认约束

Question

我的数据库中有大约 150 个表，现在我需要为每个表添加一个列约束 (InsertedOn)，默认值为 GetDate()

我试过下面的代码来完成任务

exec sp_msforeachtable 'ALTER TABLE ? ADD CONSTRAINT DF_InsertedOn DEFAULT GetDate() FOR [InsertedOn]';

但我的问题是约束名称，上面的代码在尝试为第二个表创建约束时失败，因为正在使用的约束名称

有没有办法使用相同的 sp_msforeachtable 完成任务？

谢谢。

Answer 1

试试这个 -

DECLARE @SQL NVARCHAR(MAX)
SELECT @SQL = STUFF((
    SELECT CHAR(13) + 'ALTER TABLE [' + s.name + '].[' + o.name  + '] 
        ADD [InsertedOn] DATETIME NOT NULL CONSTRAINT [DF_' + o.name + '_InsertedOn] DEFAULT GETDATE()'
    FROM sys.objects o WITH (NOWAIT)
    JOIN sys.schemas s WITH (NOWAIT) ON o.[schema_id] = s.[schema_id]
    WHERE NOT EXISTS(
            SELECT 1
            FROM sys.columns c WITH (NOWAIT)
            WHERE c.[object_id] = o.[object_id]
                AND c.name = 'InsertedOn'
        )
        AND o.[type] = 'U'
    FOR XML PATH(''), TYPE).value('.', 'NVARCHAR(MAX)'), 1, 1, '')

PRINT @SQL
EXEC sys.sp_executesql @SQL

输出-

ALTER TABLE [tt].[t1] 
ADD [InsertedOn] DATETIME NOT NULL CONSTRAINT [DF_t1_InsertedOn] DEFAULT GETDATE()
ALTER TABLE [tt].[t2] 
ADD [InsertedOn] DATETIME NOT NULL CONSTRAINT [DF_t2_InsertedOn] DEFAULT GETDATE()