xslt - 如何在 apache fop 中使用 `xsl:include`

Question

我使用 apache FOP 生成 pdf 文件。我有这个 xsl 代码

<xsl:stylesheet version="1.0"
  xmlns:xsl="http://www.w3.org/1999/XSL/Transform" xmlns:fo="http://www.w3.org/1999/XSL/Format">
  <xsl:output method="xml" indent="yes" />
  <xsl:template match="/">
    <fo:root font-size="11pt" font-family="serif">
      <fo:layout-master-set>
        <fo:simple-page-master master-name="A4-portrait"
          page-height="29.7cm" page-width="21.0cm" margin-top="1cm"
          margin-left="1.5cm" margin-right="1cm" margin-bottom="1cm">
          <fo:region-body />
          <fo:region-after region-name="footer" extent="15mm"/>
        </fo:simple-page-master>
        <fo:simple-page-master master-name="A4-landscape"
          page-width="29.7cm" page-height="21.0cm" margin-top="1cm"
          margin-left="1cm" margin-right="1cm" margin-bottom="1cm">
          <fo:region-body />
          <fo:region-after region-name="footer2" display-align="after" extent="0cm"/>
        </fo:simple-page-master>
      </fo:layout-master-set>
      <fo:page-sequence master-reference="A4-portrait">
        <xsl:include href="footer_common.xsl"/>
        <fo:flow flow-name="xsl-region-body">
          ....
        </fo:flow>
      </fo:page-sequence>
    </fo:root>
  </xsl:template>
</xsl:stylesheet>

注意元素 <xsl:include href="footer_common.xsl"/> 包含不起作用! 这是 footer_common.xsl:

<xsl:stylesheet xmlns:xsl="http://www.w3.org/1999/XSL/Transform" xmlns:fo="http://www.w3.org/1999/XSL/Format"
     version="1.0">
  <fo:static-content flow-name="footer" font-size="7pt">
    <fo:table>
      <fo:table-column column-width="70mm"/>
      <fo:table-column column-width="70mm"/>
      <fo:table-column column-width="70mm"/>
      <fo:table-body>
        ...........
      </fo:table-body>
    </fo:table>
  </fo:static-content>
</xsl:stylesheet>

两个 .xsl 文件都在同一个资源目录中。如果重要的话——我使用 eclipse 进行开发。在我的 java 代码中，我将主 .xsl 文件作为资源流并将其用于转换。

错误信息是 xsl:include ist an dieser Position in der Formatvorlage nicht zulässig! 这意味着，xsl:include is not allowed at that position in the template

谁能看出我做错了什么？

感谢任何帮助或提示。

Answer 1

xsl:include 是顶级元素(实际上是样式表 declaration )，这意味着它只能作为 xsl:stylesheet 的直接子元素出现>。因此，您根本无法在 fo:page-sequence 元素中包含样式表。

但我认为您不需要xsl:include 和一个单独的样式表，而是需要xsl:call-template 和一个单独的named template。 .

单独写一个类似下面的模板:

<xsl:template name="footer-ebase">
  <fo:static-content flow-name="footer" font-size="7pt">
    <fo:table>
      <fo:table-column column-width="70mm"/>
      <fo:table-column column-width="70mm"/>
      <fo:table-column column-width="70mm"/>
      <fo:table-body>
        <!--...-->
      </fo:table-body>
    </fo:table>
  </fo:static-content>
</xsl:template>

在主模板(您要插入内容的地方)中，引用命名模板:

<fo:page-sequence master-reference="A4-portrait">
    <xsl:call-template name="footer-ebase"/>
    <fo:flow flow-name="xsl-region-body">
    <!--...-->
    </fo:flow>
</fo:page-sequence>

---

请注意，编写命名模板并不总是有意义的。如果

• 否则您的代码将是多余的，因为您需要在多个地方使用相同的功能
• 代码会使模板困惑并难以阅读
• 你使用递归来解决问题

如果你想无缘无故地将内容拆分到单独的模板中，那么你最好一起取消它。

如果愿意，您仍然可以将命名模板放入单独的样式表中，但是您需要使用 xsl:include 作为顶级元素:

<xsl:stylesheet version="1.0" xmlns:xsl="http://www.w3.org/1999/XSL/Transform" >
    <xsl:include href="footer-ebase.xsl"/>
    <!--...-->
</xsl:stylesheet>