haskell - Haskell RNG 和状态

Question

作为一个学习 Haskell 的 Java 人，我已经习惯了思考一切的新方法，但我花了半天时间尝试用简单的 RNG 实现一些东西，但一无所获。在 Java 中，我可以创建一个静态 RNG 并使用 Classname.random.nextInt(10) 调用它，它会满足以下条件:

1. 我不必保留对 RNG 的引用，我可以临时调用它(即使在循环或递归函数内部)
2. 每次调用都会产生一个新的随机数
3. 每次执行项目时都会产生一组新的随机数

到目前为止，在 Haskell 中，我面临着经典的程序员困境——我可以拥有 2/3。我仍在学习并且对 Monad 完全一无所知，除了它们可能能够在这方面帮助我。

我最近的尝试是这样的:

getRn :: (RandomGen g) => Int -> Int -> Rand g Int
getRn lo hi= getRandomR (lo,hi)

--编辑:修剪我的问题，这样它就不会那么冗长，用摘要代替，然后我最终做了什么:

在创建了一堆随机城市(对于 TSP)之后，我使用一个函数 createEdges 将它们映射到它们上面，该函数获取一个城市并将其连接到其余城市:M.mapWithKey (\x y -> (x,(createEdges y [1..3] makeCountry)))

问题:

我想用随机的东西替换 [1..3]。 IE。我想在纯代码上映射随机性 (IO)。这给我造成了无穷无尽的困惑(请参阅下面人们试图回答我的尝试，以更好地了解我的困惑)。事实上，我什至不确定我是否正确地解释了问题。

我遇到了这种类型的错误:Couldn't match expected type [Int] with actual type IO [Int]

解决方案:

因此，在发现我想做的事情在功能环境中是根本错误的之后，我决定改变我的方法。我没有生成城市列表然后应用随机性来连接它们，而是创建了一个 [[Int]]，其中每个内部列表代表随机边缘。从而在流程开始时创建我的随机性，而不是试图将随机性映射到纯代码上。

(我将最终结果发布为我自己的答案，但现在还不允许我接受我自己的答案。一旦我达到了那个阈值，我就会回来接受)

Answer 1

如果您愿意，您可以在没有任何 monad 或 IO 的情况下使用随机数。 您只需要知道，由于涉及到状态(随机数生成器的内部状态)，因此您必须接受该状态。

在我看来，最简单的框架是 Sytem.Random .

使用这个你的 getRn 函数看起来像这样:

getRn :: (RandomGen g) => Int -> Int -> g -> (Int, g)
getRn lo hi g = randomR (lo,hi) g

在这里你可以将 g 视为我上面提到的 state - 你把它放进去然后你会像这样(在 ghci 中)得到另一个回来:

> let init = mkStdGen 11
> let (myNr, nextGen) = getRn 1 6 init
> myNr
6
> let (myNr, nextGen') = getRn 1 6 nextGen
> myNr
4

我认为你可以从使用这个开始 - 围绕 gen 进行线程化，稍后当你得到所有 monad 的东西时回来并使其更容易编写/阅读。

我不知道你的数据的定义，但这里有一个使用这种技术的简单例子:

module StackOQuestion where

import System.Random

getRn :: (RandomGen g) => Int -> Int -> g -> (Int, g)
getRn lo hi = randomR (lo,hi)

getRnList :: (RandomGen g) => (g -> (a, g)) -> Int -> g -> ([a], g)
getRnList f n g
  | n <= 0    = ([], g)
  | otherwise = let (ls, g') = getRnList f (n-1) g
                    (a, g'') = f g'
                in  (a:ls, g'')

type City = (Int, Int)

randomCity :: (RandomGen g) => g -> (City, g)
randomCity g =
    let (f, g')  = getRn 1 6 g
        (s, g'') = getRn 1 6 g'
    in  ((f, s), g'')

randomCities :: (RandomGen g) => (Int, Int) -> g -> ([City], g)
randomCities (minC, maxC) g = 
  let (count, g') = getRn minC maxC g 
  in getRnList randomCity count g'

你可以这样测试它:

> let init = mkStdGen 23
> randomCities (2,6) init
([(4,3),(1,2)],394128088 652912057)

如您所见，这会创建两个 Cities(此处仅表示为整数对)- 对于 init 的其他值，您将得到其他答案。

如果你以正确的方式看这里，你可以看到那里已经有一个 state-monad 的开始(g -> ('a, g) 部分) ;)

PS:mkStdGen 有点像您从 Java 和 co 了解到的随机初始化(您通常将系统时钟的滴答计数放入其中的部分)- 我选择 11，因为它是快速输入 ;) - 当然，如果你坚持使用 11，你总是会得到相同的数字 - 所以你需要用 IO 中的东西初始化它 - 但你可以将这个包推送到 main 并保留pure 否则如果你只是通过 g around