php - 使用 Perl 或 PHP 的 HTTP 多部分响应

Question

是否可以像多部分请求一样提供 HTTP 多部分响应(使用 Perl/PHP)？场景是这样的，我想提供一个 URL，它接受一个 EmployeeID 参数，作为返回，响应应该包括员工的照片、最新的工资单和姓名、年龄和地址等信息。接收端不是浏览器，而是一个获取此响应并稍后处理它们的程序。关于如何执行此操作的任何想法？

为了提供关于我的上述问题的更多信息，我必须向我的 friend 提供一个 URL，他将以编程方式接收响应。例如(在 Perl 中):

$response = $ua->request($my_url)

我的应用程序应该不仅响应数据，还响应文件!我被要求返回多部分响应。

我不知道如何从编码本身着手。谷歌搜索“多部分响应”没有返回我可以学习和开始的页面。然而，chansen 的评论以及他的代码示例非常有帮助 https://gist.github.com/1391017 .非常感谢。

Answer 1

我摆出我的原图 https://gist.github.com/1391017作为回应。

#!/usr/bin/perl
use strict;
use warnings;

use HTTP::Response;

my $response = HTTP::Response->new(
    200, 'OK', [ 'Content-Type' => 'multipart/form-data' ]
);

$response->protocol('HTTP/1.1');
$response->date(time);
$response->server('Foo/1.0');

my $name = HTTP::Message->new([
    'Content-Type'        => 'text/plain; charset=UTF-8',
    'Content-Disposition' => 'form-data; name="name"',
], 'John Doe');

$response->add_part($name);

my $note = HTTP::Message->new([
    'Content-Type'        => 'text/plain; charset=UTF-8',
    'Content-Disposition' => 'form-data; name="note"',
], <<'NOTE');
Resources:
  o http://search.cpan.org/dist/HTTP-Message/lib/HTTP/Message.pm
  o http://search.cpan.org/dist/HTTP-Message/lib/HTTP/Response.pm
  o http://tools.ietf.org/html/rfc2388
  o http://tools.ietf.org/html/rfc2616
NOTE

$response->add_part($note);

my $blob = HTTP::Message->new([
    'Content-Type'        => 'application/octet-stream',
    'Content-Disposition' => 'form-data; name="blob"; filename="blob.bin"',
]);
$blob->add_content('a chunk');
$blob->add_content(' of data');

$response->add_part($blob);

print $response->as_string;

输出:

HTTP/1.1 200 OK
Date: Thu, 24 Nov 2011 10:03:25 GMT
Server: Foo/1.0
Content-Type: multipart/form-data; boundary=xYzZY

--xYzZY
Content-Type: text/plain; charset=UTF-8
Content-Disposition: form-data; name="name"

John Doe
--xYzZY
Content-Type: text/plain; charset=UTF-8
Content-Disposition: form-data; name="note"

Resources:
  o http://search.cpan.org/dist/HTTP-Message/lib/HTTP/Message.pm
  o http://search.cpan.org/dist/HTTP-Message/lib/HTTP/Response.pm
  o http://tools.ietf.org/html/rfc2388
  o http://tools.ietf.org/html/rfc2616

--xYzZY
Content-Type: application/octet-stream
Content-Disposition: form-data; name="blob"; filename="blob.bin"

a chunk of data
--xYzZY--