oracle - 在多个 pl/sql 调用中部分使用游标而不在包规范中定义它

Question

我有一个大型源数据集(几百万行)，需要进行复杂的处理，导致数据量大得多，然后应将其卸载并存储为文件。存储需要根据一定的参数对结果数据进行划分，即满足一定条件的N个源行。

由于可以在 PL/SQL 中计算上述参数，因此决定最有效的方法是创建一个包，为其中的源行指定一个规范级游标，然后编写一个过程，该过程将部分使用打开的游标直到满足条件并用结果数据填充临时表，然后将卸载这些数据，然后再次调用该过程，重复直到没有更多的源行。 PL/SQL 基本上是这样的:

create or replace PACKAGE BODY generator as

  cursor glob_cur_body(cNo number) is
    select *
      from source_table
     where no = cNo
     order by conditions;

  procedure close_cur is
  begin
    if glob_cur_body%isopen then
      close glob_cur_body;
    end if;
  end close_cur;

  procedure open_cur(pNo number) is
  begin
    close_cur; 
    open glob_cur_body(pNo);
  end open_cur;

  function consume_cur return varchar2 is
    v source_table%rowtype;
    part_id varchar2(100);
  begin
    fetch glob_cur_body into v;
    if glob_cur_body%notfound then
      return null;
    end if;
    --Clear temporary tables
    --Do the processing until criteria is meet of there's no more rows
    --Fill the temporary tables and part_id
    return part_id;
  end consume_cur;
end generator;

消费者正在执行以下操作(伪代码)

generator.open_cur;
part_id = generator.consume;
while ( part_id != null )
{
//offload data from temp tables
part_id = generator.consume;
}
generator.close_cur;

它工作正常，但不幸的是有一个问题:规范级游标使包有状态，这意味着它的重新编译结果对于之前已经访问过它的 session 产生 ORA-04068。它使维护变得很麻烦，因为除了上述功能之外，包中还有很多其他功能，而且它经常用于不相关的目的。

所以，我想去掉规范级别的游标，但我不确定这是否可行。我已经放弃的一些想法:

• 重新打开游标并跳过 N 行:糟糕的性能，不可靠，因为会受到打开之间对数据所做的任何更改的影响

• 正在将源游标提取到 plsql 表中:大小太大。

• 一次填满整个卸载表，稍后拆分它们:大小太大，性能不佳。

• 将游标作为 refcursor 打开并将 refcursor 变量存储在专用包中:不可能，因为 pl/sql 在规范级别不允许 sys_refcursor 变量

• 让 open_cur 过程返回 refcursor，将其存储在卸载程序中，然后以某种方式将其传递给 consume_cur:看起来可行，但卸载程序是用 Java 编写的，并且 JDBC 不允许绑定(bind) SYS_REFCURSOR 参数。

• 将 consume_cur 更改为流水线函数:本来可以工作，但 oracle 缓冲流水线行，这意味着它会在逐行获取数据时执行多次。同样违反直觉。

到目前为止我唯一的想法是制作一个专用包来存储所述游标，具有 open 和 close 过程以及 get_cursor返回引用；然后从 generator.consume_cur 调用 get_cursor。这将使专用包(不太可能更改)有状态而主包无状态。然而，它看起来像是一个半生不熟的补丁，而不是一个问题解决方案。有没有更体面的方式来实现我的需要？也许在不影响性能和存储限制的情况下完全改变逻辑。

Answer 1

我无法理解您的问题。但我可以为你的想法提供澄清。

1. Opening the cursor as refcursor and storing refcursor variable in a dedicated package: impossible, as pl/sql doesn't allow sys_refcursor variables at spec levels

dbms_sql 的解决方法。

create table test_rows as  (select level rr from dual connect by level <= 100);

create or replace package cursor_ctx is 
 ctx_number integer;
end;  


declare 
 p_cursor sys_refcursor;
begin
 open p_cursor for 'select rr from test_rows'; 
  cursor_ctx.ctx_number := DBMS_SQL.TO_CURSOR_NUMBER(p_cursor);
end;

这部分消耗的是来自游标的数据。

declare 
 p_cursor sys_refcursor;
 type l_number is table of number;
 v_numbers l_number;
begin
  if  DBMS_SQL.IS_OPEN(cursor_ctx.ctx_number) then
    p_cursor := DBMS_SQL.TO_REFCURSOR(  cursor_ctx.ctx_number);
    fetch p_cursor bulk collect into v_numbers limit 10;
        if v_numbers.count < 10 then 
            dbms_output.put_line('No more data, close cursor');
            close p_cursor;
            cursor_ctx.ctx_number := null;
        else 
            cursor_ctx.ctx_number := DBMS_SQL.TO_CURSOR_NUMBER(p_cursor);
        end if;
        for i in nvl(v_numbers.first,1) .. nvl(v_numbers.last,-1) loop
            dbms_output.put_line(v_numbers(i));
           end loop;
    else 
     dbms_output.put_line('Null or cursor close ');
    end if;    
end;

1. 流水线函数可以将输入游标拆分成 block 。 Parallel Enabled Pipelined Table Functions

2. JDBC 允许使用 sys_refcursor 作为输出参数。 sys_refcursor = 结果集。