我正在创建一个桌面 Java 应用程序,并希望创建两个版本:免费和付费。不同之处主要在于包含哪些资源文件(在将来,它可能还会涉及不同的代码,但不是现在)。
我读过 Android build variants通过“产品 flavor ”允许这种事情。然而,这似乎是 android
独有的功能。插件,显然在桌面上不可用。
是否有与这些产品 flavor 等效且不依赖于 android
的产品?插入?
如果有帮助,我的最终目标是找到一种可以运行 Gradle build
的方法任务并输出应用程序的两个不同版本,这是我对 Android 构建变体完成什么的理解。
最佳答案
当然可以使用 sourceSets
并定制Jar
任务来达到同样的效果。
group 'com.jbirdvegas.example'
version '1.0-SNAPSHOT'
repositories {
jcenter()
}
// adding the java plugin add the `jar` task to the build task graph
apply plugin: 'java'
compileJava {
sourceCompatibility = JavaVersion.VERSION_1_8
targetCompatibility = JavaVersion.VERSION_1_8
}
/**
* SourceSets allows different builds to have their own
* code. If main and flavorOne contain com.foo.Bar then
* the `flavorOne` jar will contain the file specified by
* the `flavorOne` source set files.
*/
sourceSets {
main {
// you could also do per sourceSet resources if needed
java.srcDir 'src/main/java'
}
flavorOne {
java.srcDir 'src/flavorOne/java'
}
flavorTwo {
java.srcDir 'src/flavorTwo/java'
}
}
/**
* Creates the first flavor's jar when the Java plugin's `Jar`
* task is called. Since the `jar` task depends on `flavorOne` task
* this task will run before the generic `jar` task which produces
* the base .jar artifact.
*/
task flavorOne(type: Jar) {
from sourceSets.flavorOne.output
classifier = 'flavorOneJar'
manifest {
attributes "Main-Class": "de.jeha.photo.mosaic.cli.Main"
}
}
/**
* Creates the second flavor's jar when the Java plugin's `Jar`
* task is called. `flavorTwo` can run before `flavorOne` because
* both must just run before the `jar` task (base artifact)
*/
task flavorTwo(type: Jar) {
from sourceSets.flavorTwo.output
classifier = 'flavorTwoJar'
manifest {
attributes "Main-Class": "de.jeha.photo.mosaic.cli.Main"
}
}
// be sure to build all flavors whenever the `jar` task runs
jar.dependsOn flavorOne, flavorTwo
dependencies {
// you can declare different dependencies per sourceSets
flavorOneCompile 'com.google.code.gson:gson:2.5'
flavorTwoCompile 'com.something:else:1.0'
compile 'commons-io:commons-io:2.4'
testCompile group: 'junit', name: 'junit', version: '4.11'
}
/**
* if you want to have specific control over the main jar's
* build then you could configure the main jar as needed.
* This is the equivalent of the `flavorBlah` tasks except
* this task was added for us by the `java` plugin. Changes
* here will only affect the main jar built from `sourceSet.main`
*
* Think of this as the default where other `productFlavors` are
* completely divorced from this jar's configuration.
*/
jar {
manifest {
attributes "Main-Class": "de.jeha.photo.mosaic.cli.Main"
}
}
然后我们可以看到不同的构建。我们的口味和
main
源集 jar。$ ls -l build/libs/
-rw-r--r-- 1 jbirdvegas 63209268 1.3K Jan 6 08:58 my-sweet-jar-1.0-SNAPSHOT-flavorOneJar.jar
-rw-r--r-- 1 jbirdvegas 63209268 302B Jan 6 08:58 my-sweet-jar-1.0-SNAPSHOT-flavorTwoJar.jar
-rw-r--r-- 1 jbirdvegas 63209268 18K Jan 6 08:58 my-sweet-jar-1.0-SNAPSHOT.jar
关于gradle - 相当于非 Android Gradle 中的产品 flavor ?,我们在Stack Overflow上找到一个类似的问题: https://stackoverflow.com/questions/34604986/