json - 如何将 Text.JSON.Generic 与可选 JSON 字段一起使用？

Question

是否可以将 Text.JSON.Generic 与包含可选字段的 JSON 记录类型一起使用？如果我将 Haskell 类型声明为 Maybe a，我希望这会“正常工作”，例如:

import Text.JSON.Generic

data Record = Record {
   myMandatoryField :: Integer,
   myOptionalField :: Maybe Integer
} deriving (Eq, Show, Data, Typeable)

但这并不正确。

如果无法使可选字段与 Text.JSON.Generic 一起使用，是否有替代的 Haskell-JSON 数据绑定(bind)库可以与可选字段一起使用？

Answer 1

这似乎是基于泛型解析的一个已知问题。 Aeson遇到了同样的问题，维护人员决定弃用该功能，转而支持基于模板 Haskell 的策略:https://github.com/bos/aeson/issues/118

使用 Aeson，您的代码看起来会非常相似:

import Data.Aeson
import Data.Aeson.TH

data Record = Record {
    myMandatoryField :: Integer,
    myOptionalField :: Maybe Integer
} deriving (Eq, Show)

$(deriveJSON id ''Record)

这样，Maybe 字段按预期进行编码和解码:

$ ghci
λ :l Main.hs
Ok, modules loaded: Main.
λ encode $ Record 5 Nothing
"{\"myOptionalField\":null,\"myMandatoryField\":5}"
λ decode it :: Maybe Record
Just (Record {myMandatoryField = 5, myOptionalField = Nothing})

更新:正如评论中提到的，在 Aeson HEAD 中的 Template Haskell 可以省略空字段，但这还没有在 Hackage 上。您现在可以通过手写的 FromJSON/ToJSON 实例来获得这种行为:

instance FromJSON Record where
    parseJSON = withObject "record" $ \o -> Record
        <$> o .: "myMandatoryField"
        <*> o .:? "myOptionalField"

instance ToJSON Record where
    toJSON (Record manf optf) = object $ catMaybes
        [ ("myMandatoryField" .=) <$> pure manf
        , ("myOptionalField" .=) <$> optf ]