我有一组哈希值,所有哈希值都具有相同的键集,例如:
my $aoa= [
{NAME=>'Dave', AGE=>12, SEX=>'M', ID=>123456, NATIONALITY=>'Swedish'},
{NAME=>'Susan', AGE=>36, SEX=>'F', ID=>543210, NATIONALITY=>'Swedish'},
{NAME=>'Bart', AGE=>120, SEX=>'M', ID=>987654, NATIONALITY=>'British'},
]
我想编写一个子例程,使用给定的键层次结构将其转换为散列的散列:
my $key_hierarchy_a = ['SEX', 'NATIONALITY'];
aoh_to_hoh ($aoa, $key_hierarchy_a) = @_;
...
}
将返回
{M=>
{Swedish=>{{NAME=>'Dave', AGE=>12, ID=>123456}},
British=>{{NAME=>'Bart', AGE=>120, ID=>987654}}},
F=>
{Swedish=>{{NAME=>'Susan', AGE=>36, ID=>543210}}
}
请注意,这不仅会创建正确的 key 层次结构,还会删除现在冗余的 key 。
我陷入了需要在其正确的层次结构位置创建新的最内部散列的点。
问题是我不知道“深度”(即键数)。如果我有一个常数,我可以这样做:
%h{$inner_hash{$PRIMARY_KEY}}{$inner_hash{$SECONDARY_KEY}}{...} = filter_copy($inner_hash,[$PRIMARY_KEY,$SECONDARY_KEY])
所以也许我可以编写一个循环,一次添加一个级别,从哈希中删除该键,而不是将剩余的哈希添加到“当前”位置,但这有点麻烦,而且我不知道如何保持哈希散列中的“位置”...
最佳答案
use Data::Dumper;
my $aoa= [
{NAME=>'Dave', AGE=>12, SEX=>'M', ID=>123456, NATIONALITY=>'Swedish'},
{NAME=>'Susan', AGE=>36, SEX=>'F', ID=>543210, NATIONALITY=>'Swedish'},
{NAME=>'Bart', AGE=>120, SEX=>'M', ID=>987654, NATIONALITY=>'British'},
];
sub aoh_to_hoh {
my ($aoa, $key_hierarchy_a) = @_;
my $result = {};
my $last_key = $key_hierarchy_a->[-1];
foreach my $orig_element (@$aoa) {
my $cur = $result;
# song and dance to clone an element
my %element = %$orig_element;
foreach my $key (@$key_hierarchy_a) {
my $value = delete $element{$key};
if ($key eq $last_key) {
$cur->{$value} ||= [];
push @{$cur->{$value}}, \%element;
} else {
$cur->{$value} ||= {};
$cur = $cur->{$value};
}
}
}
return $result;
}
my $key_hierarchy_a = ['SEX', 'NATIONALITY'];
print Dumper(aoh_to_hoh($aoa, $key_hierarchy_a));
根据@FM 的评论,您确实需要一个额外的数组级别。
输出:
$VAR1 = {
'F' => {
'Swedish' => [
{
'ID' => 543210,
'NAME' => 'Susan',
'AGE' => 36
}
]
},
'M' => {
'British' => [
{
'ID' => 987654,
'NAME' => 'Bart',
'AGE' => 120
}
],
'Swedish' => [
{
'ID' => 123456,
'NAME' => 'Dave',
'AGE' => 12
}
]
}
};
编辑:哦,顺便说一句 - 如果有人知道如何优雅地克隆引用文献的内容,请教。谢谢!
编辑 编辑:@FM 有帮助。现在一切都好:D
关于perl - 如何从 Perl 中的散列数组创建散列散列?,我们在Stack Overflow上找到一个类似的问题: https://stackoverflow.com/questions/3849825/