oracle - 获取关联数组的键和值

Question

我的问题是我想从关联数组中获取键和值，但我只能找到如何从键中获取值。这是我发现的:

DECLARE
 TYPE assoc_array IS TABLE OF VARCHAR2(30)
 INDEX BY VARCHAR2(30);

 state_array assoc_array;
BEGIN
  state_array('Alaska') := 'Juneau';
  state_array('California') := 'Sacramento';

  dbms_output.put_line(state_array('Alaska'));
  dbms_output.put_line(state_array('California'));

END;

这会打印朱诺和萨克拉门托，但我想要这样的东西:

DECLARE
 TYPE assoc_array IS TABLE OF VARCHAR2(30)
 INDEX BY VARCHAR2(30);

 state_array assoc_array;
BEGIN
  state_array('Alaska') := 'Juneau';
  state_array('California') := 'Sacramento';

    for x in 1..state_array.count loop
    dbms_output.put_line(state_array(x).key || state_array(x).value);
    end loop;
END;

那可能吗？。提前致谢!!

Answer 1

其实有一种方法，请考虑下面的代码

declare
   type assoc_array is table of varchar2(30) index by varchar2(30);

   state_array assoc_array;
   l_idx varchar2(30);
begin
   state_array('Alaska') := 'Juneau';
   state_array('California') := 'Sacramento';

   l_idx := state_array.first;
   while (l_idx is not null) loop
      dbms_output.put_line('Key = ' || l_idx || ':Value = ' || state_array(l_idx));
      l_idx := state_array.next(l_idx);
   end loop;
end;

输出将是

Key = Alaska:Value = Juneau
Key = California:Value = Sacramento