vba - Word VBA 2010 - 格式化表格单元格中的最后一段

Question

我有一个从 MadCap Flare 导出到 Word 2010 的项目，我使用 VBA 脚本来更新文档的格式。我试图检查文档中每个段落的样式，然后如果它与特定样式匹配，则应用多列表级别格式。

它几乎可以毫无问题地工作。当该段落成为表格单元格中的最后一段时，就会出现问题。在这种情况下，范围包括单元格标记的结尾(因此范围包括单元格的每个段落)，因此更改适用于表格单元格中的每个段落，而不仅仅是最后一个段落。

我使用的代码如下:

For Each iPara In ActiveDocument.Paragraphs
    With iPara.Range
        If iPara.Style.NameLocal = "div_NoteText" Then
            .ListFormat.ApplyListTemplateWithLevel ListTemplate:= _
            ListGalleries(wdOutlineNumberGallery).ListTemplates(1), _
            ContinuePreviousList:=False, ApplyTo:=wdListApplyToWholeList, _
            DefaultListBehavior:=wdWord10ListBehavior, ApplyLevel:=1
        End If
    End With
Next

我需要做哪些更改才能使其适用于表格单元格中的最后一段？

Answer 1

“单元格结尾”标记是 Chr(13) + Chr(7)，因此您可以使用类似于以下的代码检测位于单元格末尾的段落:

Sub Tester()
Dim EOC As String
Dim p As Paragraph
Dim rng As Range

    EOC = Chr(13) & Chr(7)

    For Each p In ActiveDocument.Paragraphs

        If Len(p.Range.Text) > Len(EOC) And p.Range.Text Like "*" & EOC Then
               Set rng = p.Range

               'commenting out next line will select the whole cell
               rng.MoveEnd wdCharacter, -1  

               rng.Select
               MsgBox "Found paragraph at end of cell..."
        End If

    Next p

End Sub