macros - 使用 gen-class 的 clojure 宏不会创建注释

Question

我正在尝试编写一个 clojure 宏，该宏将用于在编译时生成多个 Java 类。我发现当我在宏之外调用 gen-class 时，我可以向类添加注释。但是，当我尝试在宏中使用 gen-class 时，编译的类没有注释。

我把我的问题归结为这个例子:

(gen-class
  :name ^{Deprecated true} Test1
  :prefix Test1-
  :methods [[^{Deprecated true} getValue [] Integer]])

(defn Test1-getValue [] 42)

(defmacro create-test-class [name x]
  (let [prefix (str name "-")]
    `(do
      (gen-class
         :name ~(with-meta name {Deprecated true})
         :prefix ~(symbol prefix)
         :methods [[~(with-meta 'getValue {Deprecated true}) [] Integer]])
      (defn ~(symbol (str prefix "getValue")) [] ~x))))

(create-test-class Test2 56)

当我编译这个文件时，它会创建一个 Test1.class 和 Test2.class - 我用 Eclipse 进行检查，发现 Test1 具有类级和方法级 @Deprecated 注释，但 Test2.class 没有注释。当我使用 macroexpand 时，看起来我的 Test2.class 应该被注释:

user=> (set! *print-meta* true)
true
user=> (macroexpand '(create-test-class Test2 56))
(do (clojure.core/gen-class :name ^{java.lang.Deprecated true} Test2 :prefix Test2- :methods [[^{java.lang.Deprecated true} getValue [] java.lang.Integer]]) (user/defn Test2-getValue [] 56)) 

我在这里做错了什么？

Answer 1

梅克尔·布兰德迈耶在这里回答了这个问题:

https://groups.google.com/forum/#!topic/clojure/Ee1bVwcUT-c

“引用宏中的注释。(带有元名称`{Deprecated true})。注意反引号。”

这是工作宏:

(defmacro create-test-class [name x]
  (let [prefix (str name "-")]
    `(do
      (gen-class
         :name ~(with-meta name `{Deprecated true})
         :prefix ~(symbol prefix)
         :methods [[~(with-meta 'getValue `{Deprecated true}) [] Integer]])
      (defn ~(symbol (str prefix "getValue")) [] ~x))))