entity-framework - f#:LINQ to Entities 中仅支持无参数构造函数和初始值设定项

Question

我正在尝试从查询中取回信封。信封定义如下。

[<CLIMutable>]
type Envelope<'T> = {
    Id : Guid
    StreamId: Guid
    Created : DateTimeOffset
    Item : 'T }

MyLibAAS.DataStore.MyLibAASDbContext 是用 c# 编写的 EF DbContext。当我按如下方式在 f# 中扩展它时，出现错误:Only parameterless constructors and initializers are supported in LINQ to Entities.

type MyLibAAS.DataStore.MyLibAASDbContext with 
    member this.GetEvents streamId = 
        query {
            for event in this.Events do
            where (event.StreamId = streamId)
            select {
                Id = event.Id;
                StreamId = streamId;
                Created = event.Timestamp;
                Item = (JsonConvert.DeserializeObject<QuestionnaireEvent> event.Payload)
            }
        } 

如果我在事后返回事件并将其映射到信封，它工作正常。

type MyLibAAS.DataStore.MyLibAASDbContext with 
    member this.GetEvents streamId = 
        query {
            for event in this.Events do
            where (event.StreamId = streamId)
            select event
        } |> Seq.map (fun event ->
                {
                    Id = event.Id
                    StreamId = streamId
                    Created = event.Timestamp
                    Item = (JsonConvert.DeserializeObject<QuestionnaireEvent> event.Payload)
                }
            )

为什么这会有所作为？ Envelope 类型甚至不是 EF 类型。

Answer 1

F# 记录的工作原理
F# 记录被编译为具有只读属性的 .NET 类和一个将所有字段的值作为参数的构造函数(加上一些接口(interface))。
例如，您的记录将在 C# 中大致表示如下:

public class Envelope<T> : IComparable<Envelope<T>>, IEquatable<Envelope<T>>, ...
{
   public Guid Id { get; private set; }
   public Guid StreamId { get; private set; }
   public DateTimeOffset Created { get; private set; }
   public T Item { get; private set; }

   public Envelope( Guid id, Guid streamId, DateTimeOffset created, T item ) {
      this.Id = id;
      this.StreamId = streamId;
      this.Created = created;
      this.Item = item;
   }

   // Plus implementations of IComparable, IEquatable, etc.
}

当您想要创建 F# 记录时，F# 编译器会发出对该构造函数的调用，为所有字段提供值。
例如，select您的查询的一部分在 C# 中将如下所示:

select new Envelope<QuestionnaireEvent>( 
   event.Id, streamId, event.Timestamp, 
   JsonConvert.DeserializeObject<QuestionnaireEvent>(event.Payload) )

Entity Framework 限制
碰巧 Entity Framework 不允许在查询中调用非默认构造函数。有一个很好的理由:如果确实允许，原则上你可以构造一个这样的查询:

from e in ...
let env = new Envelope<E>( e.Id, ... )
where env.Id > 0
select env

Entity Framework 不知道如何编译这个查询，因为它不知道 e.Id 的值传递给构造函数的值为属性 env.Id .对于 F# 记录总是如此，但对于其他 .NET 类则不然。
Entity Framework 原则上可以识别 Envelope是一个 F# 记录，并应用构造函数参数和记录属性之间的连接知识。但事实并非如此。不幸的是，Entity Framework 的设计者并不认为 F# 是一个有效的用例。
(有趣的事实:C# 匿名类型的工作方式相同，EF 确实为它们设置了一个异常(exception))

如何解决此问题
为了使这项工作，您需要声明 Envelope作为具有默认构造函数的类型。做到这一点的唯一方法是让它成为一个类，而不是一个记录:

type Envelope<'T>() =
   member val Id : Guid = Guid.Empty with get, set
   member val StreamId : Guid = Guid.Empty with get, set
   member val Created : DateTimeOffset = DateTimeOffset.MinValue with get, set
   member val Item : 'T = Unchecked.defaultof<'T> with get, set

然后使用属性初始化语法创建它:

select Envelope<_>( Id = event.Id, StreamId = streamId, ... )

为什么要搬select到 Seq.map工作Seq.map call 不是查询表达式的一部分。它不会成为 IQueryable 的一部分。 ，因此它最终不会被 Entity Framework 编译为 SQL。相反，EF 只编译 query 中的内容。并在从 SQL Server 获取结果序列后返回给您。只有在那之后你申请Seq.map到那个序列。Seq.map里面的代码在 CLR 上执行，而不是编译为 SQL，因此它可以调用任何它想要的东西，包括非默认构造函数。
不过，这个“修复”是有代价的:不仅仅是您需要的字段，而是整个 Event实体从数据库中获取并实现。如果这个实体很重，这可能会对性能产生影响。

另一件需要注意的事情
即使您通过制作 Envelope 来解决问题一个带有默认构造函数的类型(如上面所建议的)，你仍然会遇到下一个问题:方法 JsonConvert.DeserializeObject无法编译为 SQL，因此 Entity Framework 也会提示它。您应该这样做的方式是将所有字段提取到 CLR 端，然后应用您需要的任何非 SQL 可编译转换。