generics - 将类型约束添加到派生类型F#(此代码不够通用)

Question

我有这个界面:

type IMovingFunc< 'T > =
    abstract member Add : 'T -> unit

现在，我想创建一个实现Add函数并使用(+)运算符的泛型类型:

type MovingSum< ^T >(initial : ^T) =
    let mutable sum = initial

    interface IMovingFunc< ^T> with
        member inline this.Add x = sum <- sum + x

不幸的是，我收到此错误:

This code is not sufficiently generic. The type variable ^T when ^T : (static member ( + ) : ^T * ^T -> ^T) could not be generalized because it would escape its scope.

我尝试将类型约束添加到MovingSum，但没有帮助:

type MovingSum< ^T when ^T : (static member ( + ) : ^T * ^T -> ^T)>(initial : ^T) 

您能否告诉我如何解决此问题，或者还有其他方法可以解决此问题？

Answer 1

正如Fyodor在评论中提到的那样，类型不能具有与函数相同的静态解析约束(主要是因为静态约束是使用内联处理的，而您不能真正内联整个类型)。

解决此问题的一种方法是使约束在类型中显式，然后创建具有静态成员约束的函数，该函数捕获功能并将其传递给类型。

在您的示例中，您需要+运算符，因此我们可以将adder添加为该类型的参数:

type MovingSum<'T>(initial:'T, adder:'T -> 'T -> 'T) =
    let mutable sum = initial
    interface IMovingFunc<'T> with
        member this.Add x = sum <- adder sum x

这不需要静态成员约束，但是在创建MovingSum时需要提供额外的参数。这还不错，但是您可以通过定义一个内联函数来避免这种情况，该函数创建MovingSum并捕获+运算符:

let inline movingSum initial = 
  MovingSum(initial, fun a b -> a + b) :> IMovingFunc<_>