wolfram-mathematica - 使用 mathematica 计算特征值的问题

Question

基本上我试图找到矩阵的特征值，大约需要 12 个小时。当它完成时，它说它找不到所有的特征向量(实际上几乎没有)，我对它确实找到的特征向量持怀疑态度。我真正能做的就是发布我的代码，我希望有人能给我一些建议。我对 mathematica 不是很有经验，也许运行时间慢和糟糕的结果与我有关，而不是 mathematica 的能力。感谢任何回复的人，我真的很感激。

cutoff = 500; (* set a cutoff for the infinite series *)
numStates = cutoff + 1; (* set the number of excited states to be printed *)
If[numStates > 10, numStates = 10];

    $RecursionLimit = cutoff + 256; (* Increase the recursion limit to allow for the specified cutoff *)
(* set the mass of the constituent quarks *)
m1 := mS; (* just supposed to be a constant *)
m2 := 0;

(* construct the hamiltonian *)
h0[n_,m_] := 4 Min[n,m] * ((-1)^(n+m) * m1^2 + m2^2);

v[0,m_] := 0;
v[n_,0] := 0;
v[n_,1] := (8/n) * ((1 + (-1)^(n + 1)) / 2);
v[n_,m_] := v[n - 1, m - 1] * (m/(m - 1)) + (8 m/(n + m - 1))*((1 + (-1)^(n + m))/2);

h[n_,m_] := h0[n,m] + v[n,m];

(* construct the matrix from the hamiltonian *)
mat = Table[h[n,m], {n, 0, cutoff}, {m, 0, cutoff}] // FullSimplify;

(* find the eigenvalues and eigenvectors, then reverse the order *)
PrintTemporary["Finding the eigenvalues"];
{vals, vecs} = Eigensystem[N[mat]] // FullSimplify;

$RecursionLimit = 256; (* Put the recursion limit back to the default *)

我的代码有点多，但这是它真正变慢的地方。我绝对应该提到的一点是，如果我将 m1 和 m2 都设置为零，我真的没有任何问题，但是将 m1 设置为常量会使一切变得糟糕。

Answer 1

你的问题是常数 mS仍然是象征性的。这意味着 Mathematica 正在尝试对特征值进行解析求解，而不是数值求解。如果您的问题允许您为 mS 选择一个数值你应该这样做。

您遇到的另一个不相关的问题是您正在使用递归公式，并且您想使用，例如，在下一行中的内存

v[n_, m_] := v[n, m] = v[n - 1, m - 1]*(m/(m - 1)) 
                     + (8 m/(n + m - 1))*((1 + (-1)^(n + m))/2);

额外的 v[n, m] =存储给定 n 的值和 m所以你不必一直递归到 v[0,0]每次h[n, m]在 Table[] 中被调用.

处理好这两件事后，我的旧核心 2 二人组只需不到一分钟的时间来计算特征值。