list - 为什么 Seq.tail 不是一个选项

Question

我的问题是什么时候输入Seq.为什么没有 Seq.tail功能？

在这段没有将序列转换为列表的代码中，没有Seq.tail递归函数中可用的函数。是不是因为Seq.initInfinte用于创建序列，还是有其他原因？

open System
let readList() =
    Seq.initInfinite (fun _ -> Console.ReadLine())
    |> Seq.takeWhile (fun s -> (s <> ""))
    |> Seq.map (fun x -> Int32.Parse(x))

let rec listLen list1 acc =
    if Seq.isEmpty list1 then
        acc
    else
        (* There is no Seq.tail available. Compile error. *)
        listLen (Seq.tail list1) (acc + 1)

[<EntryPoint>]
let main argv = 
    let inList = (readList())
    let inListLen = listLen inList 0
    printfn "%A"  inListLen

    0 // return an integer exit code

但是，这很好用。我很困惑为什么Seq.tail不可用，但 List.tail可用。

open System

let readList() =
    Seq.initInfinite (fun _ -> Console.ReadLine())
    |> Seq.takeWhile (fun s -> (s <> ""))
    |> Seq.map (fun x -> Int32.Parse(x))

let rec listLen list1 acc =
    if List.isEmpty list1 then
        acc
    else
        listLen (List.tail list1) (acc + 1)

[<EntryPoint>]
let main argv = 
    let inList = Seq.toList (readList())
    let inListLen = listLen inList 0
    printfn "%A"  inListLen

    0 // return an integer exit code

Answer 1

没有具体原因，只是从未添加过，仅此而已。尽管它在更高版本的 F# 中可用(在 4.0 中为规范集合 API 付出了大量努力)。

然而，人们可以为为什么 Seq.tail 提供一个常识性的论点。用处不大，甚至可能是危险的。这实际上可能是最初不添加它的原因，但我不确定。

你看，列表和序列在幕后有非常不同的表示。

列表是一种数据结构，它有两个字段:第一个元素(称为“头”)，其余元素本身就是另一个列表(称为“尾”)。所以打电话List.tail意味着仅取数据结构的第二个字段。没有复杂的处理，只取数据结构的字段之一。

另一方面，序列基本上是一个函数(称为 IEnumerable.GetEnumerator )，它返回一个可变数据结构(称为 IEnumerator )，它可以被重复“踢”(通过调用 IEnumerator.MoveNext )，产生下一项每次踢球，并改变其内部状态。
这个表示意味着，为了“删除”序列的第一个元素，必须采用原始序列并将其包装在另一个函数中，当被要求生成 IEnumerator , 将获得内部序列的 IEnumerator ，然后踢它一次，然后返回给调用者。沿着这些路线的东西(伪代码):

Tail(inner).GetEnumerator =
   let innerE = inner.GetEnumerator()
   innerE.MoveNext()
   innerE

这意味着，虽然有一个列表，但每次调用 tail使数据结构不那么复杂(少一个项目，只剩下尾部)，每次调用 tail 都有序列会使它更复杂(又一个函数包装器)。更重要的是，如果你拿一个 tail连续几次对一个序列进行迭代，然后迭代结果，您仍然会迭代整个原始序列，即使在逻辑上它对您来说看起来更短。

将此应用于您的特定案例，您的 listLen基于 Seq.tail 的实现将具有二次复杂性(与列表的线性相反)，因为每次您调用 Seq.isEmpty 时，这将有效地导致迭代到第一个未跳过的项目，并且每次递归调用 listLen将添加另一个跳过的项目来迭代。

就其值(value)而言，标准的 .NET LINQ 实际上有一个等效的操作 - 称为 .Skip ，你完全可以在 F# 中使用它:

open System.Linq

let seqTail (s: _ seq) = s.Skip(1)

或者，正如 Robert Nielsen 在评论中指出的，实际上有一个 Seq.skip即使在 F# 标准库中(我是用手机写的，当时无法验证):

let seqTail s = Seq.skip 1 s