elixir - 如何跳过特定页面的插件

Question

我正在构建带有身份验证的Phoenix应用程序。在我的路由器中，我有类似以下内容:

pipeline :browser do
    plug :accepts, ["html"]
    plug MyApp.Plugs.Authenticate
end

scope "/", MyApp do
    pipe_through :browser # Use the default browser stack

    get "/", HomeController, :show
    get "/login", SessionsController, :login
    get "/matches", MatchesController, :index
end

我想跳过/login的Authenticate插件，可以在路由器中执行此操作还是必须在Plug本身中执行此操作？

Plugs.Authenticate看起来像:

def call(conn, _) do
    case Authenticator.find_user(conn) do
        {:ok, user} ->
            assign(conn, :user, user)
        :error ->
            conn
                |> redirect(to: "/login")
                |> halt
    end
end

Answer 1

一种方法是定义一个单独的管道:

pipeline :browser do
    plug :accepts, ["html"]
end

pipeline :auth do
    plug MyApp.Plugs.Authenticate
end

scope "/", MyApp do
    pipe_through [:browser, :auth]

    get "/", HomeController, :show
    get "/matches", MatchesController, :index
end

scope "/", MyApp do
    pipe_through :browser

    get "/login", SessionsController, :login
end

这里有几件事要注意。

1)在需要身份验证的示例中，管道被链接在一起。

2)您可以多次使用同一作用域，只要实际路由是不同的，这是因为上面的路由大致编译为:

defmodule MyRouter do
  def match(conn, :get,    ["/"])
  def match(conn, :get,    ["/matches"])
  def match(conn, :get,    ["/login"])
end

您可以在http://www.chrismccord.com/blog/2014/03/13/write-less-do-more-and-have-fun-with-elixir-macros/上了解有关Phoenix路由中的宏如何工作的更多信息，直到幻灯片的结尾