visual-studio - 将静态 boost 构建链接到 VS2012 和 Win32/64 下的静态库

Question

我正在尝试构建一个静态库，以作为网络设备的 API 发布。我可以成功编译和链接库以生成 .lib 输出文件，并将它们重新定位到目录结构中，如下所示:

EyeLib
 L-Include
 |  L-PublicInterface.h
 L-Lib
 |  L-debug
 |  |   L-MyLib.lib
 |  |   L-MyLib.pdb
 |  L-release
 |      L-MyLib.lib
 L-MyLibConfig.cmake

MyLibConfig.cmake 文件非常简单，包含:

# the header file is relative to this cmake file, so get the path.
GET_FILENAME_COMPONENT( MyLib_TOPLEVEL_DIR ${CMAKE_CURRENT_LIST_FILE} PATH )
SET( MyLib_INCLUDE_DIR ${MyLib_TOPLEVEL_DIR}/include )

IF( WIN32 )
  FIND_LIBRARY( MyLib_DEBUG_LIBRARY MyLib ${MyLib_TOPLEVEL_DIR}/lib/debug )
  FIND_LIBRARY( MyLib_RELEASE_LIBRARY MyLib ${MyLib_TOPLEVEL_DIR}/lib/release )
  SET( MyLib_LIBRARIES optimized ${MyLib_RELEASE_LIBRARY} debug ${MyLib_DEBUG_LIBRARY} )
ENDIF( WIN32 )
IF( UNIX )
  FIND_LIBRARY( MyLib_LIBRARY MyLib ${MyLib_TOPLEVEL_DIR}/lib )
  SET( MyLib_LIBRARIES "${MyLib_LIBRARY}" )
  MARK_AS_ADVANCED( MyLib_LIBRARY )
ENDIF( UNIX )

# handle the QUIETLY and REQUIRED arguments
INCLUDE(FindPackageHandleStandardArgs)
FIND_PACKAGE_HANDLE_STANDARD_ARGS(MyLib DEFAULT_MSG MyLib_LIBRARIES MyLib_INCLUDE_DIR)

MARK_AS_ADVANCED( MyLib_INCLUDE_DIR )

此构建结构适用于我过去构建的一些测试库，但是当我尝试使用它构建一个简单的测试应用程序时出现链接错误，提示“error LNK1104: cannot open file 'libboost_thread -vc110-mt-s-1_54.lib'"

如果我将测试应用程序添加到与库构建相同的项目中，我可以让测试应用程序成功构建和运行。我假设这是因为库构建正在寻找要链接的 boost 库，所以它会传播到项目中的可执行文件。

我使用 b2 link=static runtime-link=static threading=multi variant=debug,release --layout=tagged 构建了 boost 1.54，并将库构建和测试应用程序构建链接到静态 MSVC 运行时 (/MT) .

任何人都可以为此提供一些帮助/建议/进一步测试吗？我需要确保所有 boost 的东西都被编译到 API 库中，这样我们的客户就不必自己安装 boost。

附加信息

如果有用，这里是库构建中的 cmakelists.txt 文件:

set(LIBRARY_OUTPUT_PATH "${CMAKE_BINARY_DIR}/lib")

set(Boost_USE_STATIC_LIBS   ON)
set(Boost_USE_MULTITHREADED ON)
find_package(Boost REQUIRED COMPONENTS system date_time regex thread chrono)
if(NOT WIN32)
  list(APPEND Boost_LIBRARIES pthread)
endif()

include_directories(${Boost_INCLUDE_DIRS})

FILE(GLOB srcs *.cpp)
FILE(GLOB headers *.h)
set(libname MyLib)

set(deps ${Boost_LIBRARIES})

#To allow compilation. std=c++0x is for accepting the access to enums, which usually is just accepted with Visual Studio
IF( NOT WIN32 )
  set (CMAKE_CXX_FLAGS "-fpermissive -std=c++0x")
ENDIF( NOT WIN32 )

SOURCE_GROUP( ${libname} FILES ${srcs} )
SOURCE_GROUP( "${libname}\\Hdr" FILES ${headers} )
add_library(${libname} ${srcs} ${headers})
target_link_libraries( ${libname} ${deps} )

Answer 1

这是设计使然。

构建静态库时，任何对该库的依赖都不会直接链接到库中。相反，在构建可执行文件时，所有库依赖项(直接和间接)都将直接链接到该可执行文件。

这也是大多数编译器处理静态库的方式。虽然 VS 确实提供了一个特殊的选项来将依赖项链接到静态库中，但这在例如上是不可能的。 gcc 而无需诉诸脏文件黑客。由于 CMake 仅支持可在所有支持的生成器上使用的功能，因此即使在 VS 构建上，CMake 也不允许这样做。

您现在有几个选择:

• 使用 dll 而不是静态库 (add_library(${libname} SHARED ...))。虽然静态库基本上是一堆包装在一起的目标文件，但 dll 或多或少与可执行文件相同。特别是，所有静态库依赖项都直接链接到 dll 中。此处的缺点是您必须处理常见的 dll 困惑:您必须指定要导出的函数以及跨 dll 边界传递内容的常见问题。
• 让您的查找脚本也搜索所有依赖项。您应该能够以一种代码重复量最少的方式重组您的库的依赖关系处理。缺点是配置第三方应用程序变得更加困难(尤其是在 Windows 上)，因为您现在不仅需要找到库本身，还需要找到它的所有依赖项。
• 使用exported targets .如果库与最终可执行文件构建在同一台机器上，则此方法最有意义。构建库后，CMake 会自动生成使用该库的配置文件。然后您的应用程序只需要找到一个包含该脚本的脚本就可以了。缺点是导出机制不是 CMake 最直接的功能，因此您需要花一些时间来熟悉它。
• 将库源代码直接拉入每个可执行文件。基本上每个可执行文件都会在库源目录上执行一个 add_subdirectory。您仍然需要为每个可执行文件配置依赖项，最重要的是您还必须为每个可执行文件单独构建库。您可能不想这样做。