Jenkinsfile - 获取构建之间的所有更改

Question

引用this question有没有办法从使用多分支管道时获取等效信息？具体来说 - 自上次成功构建以来的提交列表。

目前我们使用以下

def scmAction = build?.actions.find { action -> 
    action instanceof jenkins.scm.api.SCMRevisionAction
}
return scmAction?.revision?.hash

但这只会在推送多个提交时返回触发构建的最后一次提交。我承认一个新分支的第一个构建可能是模棱两可的，但是在可能的情况下获取触发构建的提交列表将非常有用。

Answer 1

我找到了一个似乎对我们有用的解决方案。它围绕着获得 currentBuild提交哈希，然后是 lastSuccessfulBuild提交哈希。首先，我们编写了一个实用方法来获取给定 Jenkins 构建对象的提交哈希:

def commitHashForBuild(build) {
  def scmAction = build?.actions.find { action -> action instanceof jenkins.scm.api.SCMRevisionAction }
  return scmAction?.revision?.hash
}

然后用它来获得 lastSuccessfulBuild的哈希:

def getLastSuccessfulCommit() {
  def lastSuccessfulHash = null
  def lastSuccessfulBuild = currentBuild.rawBuild.getPreviousSuccessfulBuild()
  if ( lastSuccessfulBuild ) {
    lastSuccessfulHash = commitHashForBuild(lastSuccessfulBuild)
  }
  return lastSuccessfulHash
}

最后将这两者结合在一个 sh 中获取提交列表的函数

  def lastSuccessfulCommit = getLastSuccessfulCommit()
  def currentCommit = commitHashForBuild(currentBuild.rawBuild)
  if (lastSuccessfulCommit) {
    commits = sh(
      script: "git rev-list $currentCommit \"^$lastSuccessfulCommit\"",
      returnStdout: true
    ).split('\n')
    println "Commits are: $commits"
  }

然后您可以使用 commits根据构建需要在 Git 中查询各种内容的数组。例如。您可以使用此数据获取自上次成功构建以来所有更改文件的列表。

我已经把这个变成了一个完整的example Jenkinsfile要点来展示它如何在上下文中组合在一起。

一个可能的改进是使用 Java/Groovy native Git 库，而不是炮轰到 sh步。