apache-flex - Flex 4 文件引用选定的图像文件尺寸(宽度和高度)

Question

我使用 fileReference.browse() 从硬盘中选择一个图像文件。

请问如何查看所选图片文件的宽度和高度？

谢谢!

Answer 1

使用 loadBytes() 将 fileReference.data 加载到加载器中。然后你会得到:sourceBMP:Bitmap = loader.content as Bitmap;

这是一个示例代码:

MXML 部分:

<fx:Declarations>
    <net:FileReference id="fileReference"
        select="fileReference_select(event);"
        complete="fileReference_complete(event);" />
</fx:Declarations>
<s:Button id="uplaodImageBtn"
    label="Upload Image"
    click="uplaodImageBtn_clickHandler()"/>

AS3 部分:

private function uplaodImageBtn_clickHandler() : void {
    var arr:Array = [];
    arr.push(new FileFilter("Images", ".gif;*.jpeg;*.jpg;*.png"));
    fileReference.browse(arr);
}

private function fileReference_select(evt:Event):void {
    fileReference.load();
}

private function fileReference_complete(event:Event):void {
    var loader:Loader = new Loader();
    loader.contentLoaderInfo.addEventListener(Event.COMPLETE, loader_complete);
    loader.loadBytes(fileReference.data);
}

public function loader_complete (event:Event) : void {
    var sourceBMP:Bitmap = event.currentTarget.loader.content as Bitmap;
    Alert.show(sourceBMP.width + ', ' +sourceBMP.height);
}